13.1. Percentage instroom personeel in loondienst

Concepten

• Arbeidsovereenkomst
• Inhuurovereenkomst
• Uitzendovereenkomst
• Zorgverlener (functie)

Relaties

• gaat over
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 13.1
2# Parameters: $(peildatum)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX onz-g: <http://purl.org/ozo/onz-g#>
10PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
11
12SELECT 
13	(COUNT(?werknemer) AS ?noemer)
14    (SUM(?instroom) AS ?teller)
15    (xsd:integer(ROUND(100*(SUM(?instroom)/COUNT(?werknemer)))) AS ?indicator)
16WHERE
17{
18    {
19        SELECT 
20            ?werknemer
21            (MIN(?nieuw) AS ?instroom)
22        {
23            BIND($(peildatum) AS ?peildatum)
24            BIND((?peildatum - "P1Y"^^xsd:duration) AS ?peildatum_eerder)
25
26            #Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
27            VALUES ?personeels_overeenkomst 
28            { 
29                onz-pers:ArbeidsOvereenkomst
30                onz-pers:UitzendOvereenkomst
31                onz-pers:InhuurOvereenkomst
32            }
33            ?overeenkomst 
34                a ?personeels_overeenkomst ; #Alleen personeel
35                onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ; #Alleen Zorgverlener
36                onz-pers:heeftOpdrachtnemer ?werknemer ;
37                onz-g:startDatum ?start_overeenkomst .
38            OPTIONAL {
39                ?overeenkomst onz-g:eindDatum ?eind_overeenkomst
40            }
41            FILTER (?start_overeenkomst <= ?peildatum && (?eind_overeenkomst >= ?peildatum || !BOUND(?eind_overeenkomst)))
42            #Kijk of er op peildatum - periode ook een arbeidsovereenkomst was die aan de voorwaarden voldoet
43            OPTIONAL {
44                ?overeenkomst_oud
45                    a ?personeels_overeenkomst ; #Alleen personeel
46                    onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ; #Alleen Zorgverlener
47                    onz-pers:heeftOpdrachtnemer ?werknemer ;
48                    onz-g:startDatum ?start_overeenkomst_oud .
49                OPTIONAL {
50                    ?overeenkomst_oud onz-g:eindDatum ?eind_overeenkomst_oud
51                }
52                FILTER (?start_overeenkomst_oud <= ?peildatum_eerder && (?eind_overeenkomst_oud >= ?peildatum_eerder || !BOUND(?eind_overeenkomst_oud)))
53            }
54            BIND(IF(BOUND(?overeenkomst_oud), 0, 1) AS ?nieuw)
55        }   
56        GROUP BY ?werknemer
57    }
58}