15.4.1 Aantal cliënten per financieringsstroom

Concepten

• ForensischeIndicatieStelling
• IndicatieBesluit
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.1
2# Parameters: ?peildatum ?zorgkantoor
3# Ontologie: versie 3.0.0 of nieuwer
4 
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11 
12SELECT ?vestiging
13		(COUNT(DISTINCT IF(BOUND(?zvw), ?client, ?unbound)) AS ?Aantal_clienten_Zvw)
14    	(COUNT(DISTINCT IF(BOUND(?wlz), ?client, ?unbound)) AS ?Aantal_clienten_Wlz)
15    	(COUNT(DISTINCT IF(BOUND(?wmo), ?client, ?unbound)) AS ?Aantal_clienten_Wmo)
16 		(COUNT(DISTINCT IF(!BOUND(?zvw) && !BOUND(?wlz) && !BOUND(?wmo) , ?client, ?unbound)) AS ?Aantal_clienten_Overige_zorg)
17
18WHERE {
19	#BIND ($(peildatum) AS ?peildatum)
20    
21    { 
22        ?indicatie a onz-zorg:IndicatieBesluit 
23    } UNION {
24        ?indicatie a onz-zorg:ForensischeIndicatieStelling
25    }
26    
27    ?indicatie
28    	onz-g:isAbout ?client ;
29        onz-g:startDatum ?start_indicatie .
30        OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie . }
31    FILTER (?start_indicatie <= ?peildatum && (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?peildatum))
32    
33    ?client
34        a onz-g:Human .   
35    
36    OPTIONAL {
37        ?indicatie a onz-zorg:WlzIndicatie .
38        BIND(1 AS ?wlz) .
39     }
40    OPTIONAL {
41        ?indicatie a onz-zorg:ZvwIndicatie .
42        BIND(1 AS ?zvw) .
43    }
44    OPTIONAL {
45        ?indicatie a onz-zorg:WmoIndicatie .
46        BIND(1 AS ?wmo) .
47    }
48
49    
50    # Bepaal de locatie
51    ?indicatie ^onz-g:definedBy/onz-g:hasPerdurantLocation ?locatie .
52    
53    ?locatie 
54        a onz-g:StationaryArtifact ;
55    	onz-g:partOf* ?vestiging_uri .
56    ?vestiging_uri a onz-org:Vestiging ;
57    	onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
58    
59    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
60    ?pc_gebied
61        onz-g:identifiedBy ?postcode ;
62        onz-g:partOf+ ?zk_regio .
63    ?zk_regio a onz-org:ZorgkantoorRegio .
64    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
65    
66    {
67        ?vestiging_uri onz-g:identifiedBy ?vest_nr .
68        ?vest_nr a onz-org:Vestigingsnummer ;
69                 onz-g:hasDataValue ?vestiging .
70    } UNION {
71        # Includeer ook de organisatie als geheel en label deze als vestiging
72        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
73        BIND("Totaal organisatie" AS ?vestiging)
74        BIND("n.v.t." AS ?zk_vestiging)
75    }
76    BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
77  
78}
79GROUP BY ?vestiging
80ORDER BY ?vestiging