15.4.3 Aantal cliënten met een Wlz-indicatie met zorgprofiel VV per leveringsvorm

Concepten

• Bedrijf
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• ZorgEnVerpleegProces
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.3
2# Parameters: ?peildatum
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT ?Organisatieonderdeel
12        (SUM(?verblijf) AS ?totaal_verblijf)
13        (SUM(?vpt) as ?totaal_vpt)
14        (SUM(?mpt) as ?totaal_mpt)
15        (SUM(?pgb) as ?totaal_pgb)   
16
17WHERE
18{
19    #BIND ($(peildatum) AS ?peildatum)
20
21    # Selecteer de zorgprocessen die voldoen aan de inclusiecriteria
22    ?zorgproces
23        a onz-g:CureAndCareProcess ;
24        onz-g:definedBy ?indicatie ;
25        onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie ;
26        onz-g:startDatum ?start_zorgproces .
27    OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
28    FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces))))   
29
30    # Locatie en vestiging structuur
31    ?locatie 
32        a onz-g:StationaryArtifact ;
33        onz-g:partOf* ?vestiging_uri .
34    
35    ?vestiging_uri a onz-org:Vestiging ;
36        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
37    
38    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
39    
40    ?pc_gebied 
41        onz-g:identifiedBy ?postcode ;
42        onz-g:partOf+ ?zk_regio .
43    ?zk_regio a onz-org:ZorgkantoorRegio .
44    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
45
46    {     
47        ?vestiging_uri onz-g:identifiedBy ?vest_nr .
48        ?vest_nr a onz-org:Vestigingsnummer ;
49            onz-g:hasDataValue ?vestiging .
50        BIND(?vestiging AS ?Organisatieonderdeel)
51    } UNION {
52        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
53        ?organisatie_uri 
54            a onz-g:Business ;
55            rdfs:label ?Organisatie .
56        BIND(CONCAT('Totaal ',?Organisatie) AS ?Organisatieonderdeel)
57        BIND("n.v.t." AS ?zk_vestiging)
58    }
59    
60    BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
61
62    # Selecteer Wlz indicaties en filter op zorgprofiel VV
63    ?indicatie
64        a onz-zorg:WlzIndicatie ;
65        onz-g:hasPart/onz-g:isAbout ?sector ;
66        onz-g:hasPart ?lv ;
67        onz-g:isAbout ?client .
68    ?sector
69        a onz-zorg:LangdurigeZorgSector .
70    FILTER(?sector = onz-zorg:VV)
71    ?client a onz-g:Human .
72    ?lv
73        a onz-zorg:Leveringsvorm ;
74        rdfs:label ?leveringsvorm_label .
75
76    # Per financieringsstroom
77    BIND(IF(?lv = onz-zorg:instelling, 1, 0) AS ?verblijf)
78    BIND(IF(?lv = onz-zorg:vpt, 1, 0) AS ?vpt)
79    BIND(IF(?lv = onz-zorg:mpt, 1, 0) AS ?mpt)
80    BIND(IF(?lv = onz-zorg:pgb, 1, 0) AS ?pgb)
81} 
82GROUP BY ?Organisatieonderdeel
83ORDER BY ?Organisatieonderdeel