2.9. Wat is de leeftijdsopbouw bij personeel in loondienst?

Concepten

• Arbeidsovereenkomst
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• heeft geboortedatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ActiZ 2.9
2# Parameters: ?kwartaal, ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT 
13    (?vestiging AS ?Indeling)
14    (?zk_regio_code AS ?Zorgkantoorregiocode)
15    (SUM(?1620) AS ?Leeftijd_16_20)
16    (SUM(?2125) AS ?Leeftijd_21_25)
17    (SUM(?2630) AS ?Leeftijd_26_30)
18    (SUM(?3135) AS ?Leeftijd_31_35)
19    (SUM(?3640) AS ?Leeftijd_36_40)
20    (SUM(?4145) AS ?Leeftijd_41_45)
21    (SUM(?4650) AS ?Leeftijd_46_50)
22    (SUM(?5155) AS ?Leeftijd_51_55)
23    (SUM(?5660) AS ?Leeftijd_56_60)
24    (SUM(?6165) AS ?Leeftijd_61_65)
25    (SUM(?6670) AS ?Leeftijd_66_70)
26    (SUM(?7175) AS ?Leeftijd_71_75)
27{
28    {
29        SELECT  DISTINCT 
30            ?vestiging
31            ?zk_regio_code
32            ?persoon
33            ?leeftijd
34        {
35            # BIND(2024 AS ?jaar)
36            # BIND("Q1" AS ?kwartaal)
37            # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
38            
39            BIND(IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
40                IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
41                IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
42                IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
43                '')))) AS ?start_periode)
44            BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
45            
46            ?overeenkomst 
47                a onz-pers:ArbeidsOvereenkomst ;
48                onz-pers:heeftOpdrachtnemer ?persoon ;
49                onz-g:hasPart ?overeenkomst_afspraak .
50            ?overeenkomst_afspraak
51                a onz-pers:WerkOvereenkomstAfspraak ;
52                onz-g:startDatum ?start_afspraak .
53            OPTIONAL {
54                ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
55            }
56            FILTER (?start_afspraak <= ?eind_periode && (?eind_afspraak >= ?start_periode || !BOUND(?eind_afspraak)))
57
58            ?persoon 
59                a onz-g:Human ;
60                onz-g:hasDateOfBirth ?geboortedatum .
61            
62            BIND(YEAR(?eind_periode) - YEAR(?geboortedatum) AS ?leeftijd_voorl)
63            BIND(IF(MONTH(?geboortedatum) > MONTH(?eind_periode) 
64                || (MONTH(?geboortedatum) = MONTH(?eind_periode) && DAY(?geboortedatum) > DAY(?eind_periode)), 
65                ?leeftijd_voorl - 1, ?leeftijd_voorl) AS ?leeftijd)
66        
67            # bepaal vestiging en zorgkantoor regio voor iedere contractafspraak
68            ?overeenkomst_afspraak onz-g:isAbout ?locatie .
69            ?locatie 
70                a onz-g:StationaryArtifact ;
71                onz-g:partOf* ?vestiging_uri .
72            ?vestiging_uri a onz-org:Vestiging ;
73                onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
74            BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
75            ?pc_gebied 
76                onz-g:identifiedBy ?postcode ;
77                onz-g:partOf+ ?zk_regio .
78            ?zk_regio a onz-org:ZorgkantoorRegio .
79            {     
80                ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
81                ?vest_nr a onz-org:Vestigingsnummer ;
82                    onz-g:hasDataValue ?vestiging .
83        		?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
84                 BIND(STRAFTER(STR(?zk_regio), "onz-org/") AS ?zk_regio_code)
85            } UNION {
86                # Includeer ook de organisatie als geheel en label deze als vestiging
87                ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
88                BIND("Totaal organisatie" AS ?vestiging)
89                BIND("n.v.t." AS ?zk_vestiging)
90                BIND("n.v.t." AS ?zk_regio_code)
91
92            }
93            BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
94        }
95    }
96    BIND(IF(?leeftijd >= 16 && ?leeftijd <= 20, 1, 0) AS ?1620)
97    BIND(IF(?leeftijd >= 21 && ?leeftijd <= 25, 1, 0) AS ?2125)
98    BIND(IF(?leeftijd >= 26 && ?leeftijd <= 30, 1, 0) AS ?2630)
99    BIND(IF(?leeftijd >= 31 && ?leeftijd <= 35, 1, 0) AS ?3135)
100    BIND(IF(?leeftijd >= 36 && ?leeftijd <= 40, 1, 0) AS ?3640)
101    BIND(IF(?leeftijd >= 41 && ?leeftijd <= 45, 1, 0) AS ?4145)
102    BIND(IF(?leeftijd >= 46 && ?leeftijd <= 50, 1, 0) AS ?4650)
103    BIND(IF(?leeftijd >= 51 && ?leeftijd <= 55, 1, 0) AS ?5155)
104    BIND(IF(?leeftijd >= 56 && ?leeftijd <= 60, 1, 0) AS ?5660)
105    BIND(IF(?leeftijd >= 61 && ?leeftijd <= 65, 1, 0) AS ?6165)
106    BIND(IF(?leeftijd >= 66 && ?leeftijd <= 70, 1, 0) AS ?6670)
107    BIND(IF(?leeftijd >= 71 && ?leeftijd <= 75, 1, 0) AS ?7175)
108    BIND(IF(?leeftijd >= 75 , 1, 0) AS ?75_)
109}
110GROUP BY ?vestiging ?zk_regio_code
111ORDER BY ?vestiging
112