1.3. Wat is het aantal cliënten met eerste grondslag psychogeriatrie of somatiek met leveringsvorm verblijf?

Concepten

• Mens
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• ZorgEnVerpleegProces
• Zorgkantoor regio

Relaties

• deel van
• formeel gedefinieerd door
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft deelnemer
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• Verblijf in een instelling
• psychogeriatrische aandoening of beperking
• somatische aandoening of beperking

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ActiZ 1.3
2# Parameters: ?jaar, ?kwartaal
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg:<http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13  (?vestiging AS ?Indeling)
14  (?zk_regio_code AS ?Zorgkantoorregio_code)
15  (COUNT(DISTINCT IF(?is_pg,  ?client, ?__dummy)) AS ?Aantal_met_eerste_grondslag_PG)
16  (COUNT(DISTINCT IF(?is_som, ?client, ?__dummy2)) AS ?Aantal_met_eerste_grondslag_somatiek)
17(COUNT(DISTINCT ?client) AS ?Totaal_aantal_clienten)
18WHERE {
19#BIND(2024 AS ?jaar)
20#BIND("Q1" AS ?kwartaal)
21
22
23BIND( xsd:date(CONCAT(STR(?jaar), "-",
24                        IF(?kwartaal="Q1","01-01", IF(?kwartaal="Q2","04-01", IF(?kwartaal="Q3","07-01", IF(?kwartaal="Q4","10-01", "01-01"))))
25           )) AS ?p_start )
26      BIND( xsd:date(CONCAT(STR(?jaar), "-",
27               IF(?kwartaal="Q1","03-31", IF(?kwartaal="Q2","06-30", IF(?kwartaal="Q3","09-30","12-31")))
28           )) AS ?p_eind )
29
30    ?zorgproces a onz-g:CureAndCareProcess ;
31    onz-g:definedBy ?indicatie ;
32    onz-g:hasParticipant ?client ;
33    onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie ;
34                          onz-g:startDatum ?start_zorgproces .
35    OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
36
37# Filter zorgprocessen binnen de meetperiode
38FILTER ( ?start_zorgproces <= ?p_eind &&
39  ( !BOUND(?eind_zorgproces) || ?eind_zorgproces >= ?p_start ))
40        ?client a onz-g:Human .
41# Indicaties
42  ?indicatie a onz-zorg:WlzIndicatie ;
43                      onz-g:hasPart onz-zorg:instelling ;
44		onz-g:formallyDefinedBy ?eerste_grondslag ;
45    	onz-g:definedBy ?grondslag ;
46      onz-g:startDatum ?start_ind .
47      OPTIONAL { ?indicatie onz-g:eindDatum ?eind_ind }
48      
49    # Filter indicaties binnen de meetperiode
50  FILTER ( ?start_ind <= ?p_eind &&
51  ( !BOUND(?eind_ind) || ?eind_ind >= ?p_start ))
52                
53  VALUES (?pg ?som) {
54    (onz-zorg:GrondslagPG onz-zorg:GrondslagSOM)
55  }
56    # Filter op clienten met een grondslag pg of somatiek
57    FILTER(?grondslag IN (?pg, ?som))
58    # Selecteer clienten met EERSTE grondslag pg of somatiek
59	BIND(?eerste_grondslag = onz-zorg:GrondslagPG  AS ?is_pg)
60	BIND(?eerste_grondslag = onz-zorg:GrondslagSOM AS ?is_som)
61
62         # Locatie structuur
63     {
64           # Vestigingsregel
65           ?locatie onz-g:partOf* ?vestiging_uri .
66           ?vestiging_uri a onz-org:Vestiging ;
67           onz-g:identifiedBy ?vest_nr ;
68           onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
69           ?vest_nr a onz-org:Vestigingsnummer ; onz-g:hasDataValue ?vestiging .
70
71           BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
72           ?pc_gebied onz-g:identifiedBy ?postcode ; onz-g:partOf+ ?zk_regio .
73           ?zk_regio a onz-org:ZorgkantoorRegio .
74           }
75           UNION
76           {
77           # Totaal organisatie
78           ?locatie onz-g:partOf* ?vestiging_uri .
79           ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
80           BIND("Totaal organisatie" AS ?vestiging)
81           }
82
83           BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
84   
85    
86}
87GROUP BY ?vestiging ?zk_regio_code  
88ORDER BY ?Indeling