Uitwisselprofiel ActiZ Belangenbehartiging

Over Uitwisselprofiel ActiZ Belangenbehartiging


Publicatiedatum:
11-11-2026

Inwerkingtreding:
11-11-2026

2.10 Wat is het aantal gemiddelde gewerkte periodes van personeelsleden in loondienst met een zorgverleners functie per kwalificatieniveau per Dag-, Avond- en Nacht-dienst (DAN-dienst)?

Concepten

Relaties

Eigenschappen

SPARQL query

Code gekopieerd

...

Kopieer naar klembord

1# Indicator: ActiZ 2.10 
2# Parameters: ?jaar, ?kwartaal
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g:    <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-org:  <http://purl.org/ozo/onz-org#>
8PREFIX rdf:      <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs:     <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd:      <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13  (?vestiging AS ?Indeling)
14  (?zk_regio_code AS ?Zorgkantoorregiocode)
15  (?kwalificatieniveau AS ?Kwalificatieniveau)
16  (ROUND((SUM(?isDag)   / xsd:decimal(?kalenderdagen)) * 100) / 100 AS ?Aantal_gemiddelde_gewerkte_perioden_dagdienst)
17  (ROUND((SUM(?isAvond) / xsd:decimal(?kalenderdagen)) * 100) / 100 AS ?Aantal_gemiddelde_gewerkte_perioden_avonddienst)
18  (ROUND((SUM(?isNacht) / xsd:decimal(?kalenderdagen)) * 100) / 100 AS ?Aantal_gemiddelde_gewerkte_perioden_nachtdienst)
19WHERE {
20  # BIND(2024 AS ?jaar)
21  # BIND("Q1" AS ?kwartaal)
22
23  BIND(?jaar AS ?j)
24
25  # Schrikkeljaar: standaard SPARQL (geen ofn:floorMod)
26  BIND(xsd:integer(?j) AS ?ji)
27  BIND(((?ji - (xsd:integer(?ji / 400) * 400) = 0) || ((?ji - (xsd:integer(?ji / 4) * 4) = 0) && (?ji - (xsd:integer(?ji / 100) * 100) != 0))) AS ?isSchrikkel)
28
29  BIND(
30    STRDT(
31      CONCAT(
32        STR(?j), "-",
33        IF(?kwartaal = "Q1", "01-01",
34        IF(?kwartaal = "Q2", "04-01",
35        IF(?kwartaal = "Q3", "07-01", "10-01")))
36      ),
37      xsd:date
38    ) AS ?p_start
39  )
40
41  BIND(
42    STRDT(
43      CONCAT(
44        STR(?j), "-",
45        IF(?kwartaal = "Q1", "03-31",
46        IF(?kwartaal = "Q2", "06-30",
47        IF(?kwartaal = "Q3", "09-30", "12-31")))
48      ),
49      xsd:date
50    ) AS ?p_eind
51  )
52
53  BIND(
54    IF(?kwartaal = "Q1", IF(?isSchrikkel, 91, 90),
55    IF(?kwartaal = "Q2", 91,
56    IF(?kwartaal = "Q3", 92, 92)))
57    AS ?kalenderdagen
58  )
59
60  BIND(IF(?vestiging = "Totaal organisatie", 0, 1) AS ?IndelingSort)
61
62  # DAN-venster
63  BIND(xsd:dateTime(CONCAT(STR(?p_start), "T07:00:00")) AS ?dan_start)
64  BIND(?p_eind + "P1D"^^xsd:duration AS ?eind_periode_plus)
65  BIND(xsd:dateTime(CONCAT(STR(?eind_periode_plus), "T06:59:00")) AS ?dan_end)
66
67  # Alle kwalificatieniveaus altijd tonen
68  {
69    SELECT DISTINCT ?kwalificatieniveau {
70      ?functie a onz-pers:ZorgverlenerFunctie ;
71               onz-g:hasQuality/onz-g:hasQualityValue ?functie_niveau .
72      ?functie_niveau a onz-pers:ODBKwalificatieWaarde ;
73                      rdfs:label ?kwalificatieniveau .
74    }
75  }
76
77  # Alle indelingen (vestigingen + totaal) — 1x resolutie via subquery
78  {
79    SELECT DISTINCT ?vestiging ?zk_regio_code {
80      {
81        ?vestiging_uri a onz-org:Vestiging ;
82                       onz-g:identifiedBy ?vest_nr ;
83                       onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
84        ?vest_nr a onz-org:Vestigingsnummer ;
85                 onz-g:hasDataValue ?vestiging .
86        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
87        ?pc_gebied onz-g:identifiedBy ?postcode ;
88                   onz-g:partOf+ ?zk_regio .
89        ?zk_regio a onz-org:ZorgkantoorRegio .
90        BIND(STRAFTER(STR(?zk_regio), "/onz-org/") AS ?zk_regio_code)
91      }
92      UNION
93      {
94        ?locatie_init onz-g:partOf? ?vestiging_uri .
95        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
96        BIND("Totaal organisatie" AS ?vestiging)
97        BIND("n.v.t." AS ?zk_regio_code)
98      }
99    }
100  }
101
102  OPTIONAL {
103    # Subquery: pre-resolve GewerktePeriode → vestiging (1x, niet per cross-join rij)
104    {
105      SELECT ?vestiging ?zk_regio_code ?kwalificatieniveau ?start_uur
106      WHERE {
107        # BIND(2024 AS ?jaar)
108        # BIND("Q1" AS ?kwartaal)
109
110        BIND(?jaar AS ?j2)
111        BIND(
112          STRDT(CONCAT(STR(?j2), "-",
113            IF(?kwartaal = "Q1", "01-01", IF(?kwartaal = "Q2", "04-01",
114            IF(?kwartaal = "Q3", "07-01", "10-01")))), xsd:date) AS ?p_start2)
115        BIND(
116          STRDT(CONCAT(STR(?j2), "-",
117            IF(?kwartaal = "Q1", "03-31", IF(?kwartaal = "Q2", "06-30",
118            IF(?kwartaal = "Q3", "09-30", "12-31")))), xsd:date) AS ?p_eind2)
119        BIND(xsd:dateTime(CONCAT(STR(?p_start2), "T07:00:00")) AS ?dan_start2)
120        BIND(?p_eind2 + "P1D"^^xsd:duration AS ?eind_periode_plus2)
121        BIND(xsd:dateTime(CONCAT(STR(?eind_periode_plus2), "T06:59:00")) AS ?dan_end2)
122
123        ?gewerkte_periode a onz-pers:GewerktePeriode ;
124                          onz-g:hasBeginTimeStamp ?start_werk ;
125                          onz-g:hasEndTimeStamp ?eind_werk ;
126                          onz-g:definedBy ?overeenkomst .
127        FILTER(?start_werk >= ?dan_start2 && ?start_werk <= ?dan_end2)
128
129        BIND(HOURS(?start_werk) AS ?start_uur)
130
131        ?overeenkomst a onz-pers:ArbeidsOvereenkomst ;
132                      onz-g:hasPart ?overeenkomst_afspraak .
133
134        ?overeenkomst_afspraak a onz-pers:WerkOvereenkomstAfspraak ;
135                               onz-g:startDatum ?start_afspraak ;
136                               onz-g:isAbout ?functie ;
137                               onz-g:isAbout ?locatie_afspraak .
138        OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
139        FILTER(?start_afspraak <= ?eind_periode_plus2 &&
140               (!BOUND(?eind_afspraak) || ?eind_afspraak >= ?p_start2))
141
142        ?functie a onz-pers:ZorgverlenerFunctie ;
143                 onz-g:hasQuality/onz-g:hasQualityValue ?functie_niveau .
144        ?functie_niveau a onz-pers:ODBKwalificatieWaarde ;
145                        rdfs:label ?kwalificatieniveau .
146
147        ?locatie_afspraak a onz-g:StationaryArtifact .
148        OPTIONAL { ?gewerkte_periode onz-g:hasPerdurantLocation ?locatie_werk . }
149        BIND(COALESCE(?locatie_werk, ?locatie_afspraak) AS ?locatie)
150
151        {
152          # Vestiging + regio — partOf beperkt tot 2 niveaus
153          ?locatie (onz-g:partOf)? ?vestiging_uri .
154          ?vestiging_uri a onz-org:Vestiging ;
155                         onz-g:identifiedBy ?vest_nr ;
156                         onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
157          ?vest_nr a onz-org:Vestigingsnummer ;
158                   onz-g:hasDataValue ?vestiging .
159          BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
160          ?pc_gebied onz-g:identifiedBy ?postcode ;
161                     onz-g:partOf+ ?zk_regio .
162          ?zk_regio a onz-org:ZorgkantoorRegio .
163          BIND(STRAFTER(STR(?zk_regio), "/onz-org/") AS ?zk_regio_code)
164        }
165        UNION
166        {
167          # Totaal organisatie — partOf beperkt tot 2 niveaus
168          ?locatie (onz-g:partOf)? ?vestiging_uri .
169          ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
170          BIND("Totaal organisatie" AS ?vestiging)
171          BIND("n.v.t." AS ?zk_regio_code)
172        }
173      }
174    }
175  }
176
177  # Indicatorvariabelen
178  BIND(IF(BOUND(?start_uur) && (?start_uur >= 7  && ?start_uur < 15), 1, 0) AS ?isDag)
179  BIND(IF(BOUND(?start_uur) && (?start_uur >= 15 && ?start_uur < 23), 1, 0) AS ?isAvond)
180  BIND(IF(BOUND(?start_uur) && (?start_uur >= 23 || ?start_uur < 7),  1, 0) AS ?isNacht)
181}
182GROUP BY
183  ?vestiging
184  ?IndelingSort
185  ?zk_regio_code
186  ?kwalificatieniveau
187  ?kalenderdagen
188ORDER BY ?IndelingSort ?vestiging ?kwalificatieniveau
189