1.2.3. Aantal personeelsleden per kwalificatieniveau

Concepten

• Mens
• ODB Kwalificatiewaarde
• Zorgverlener (functie)

Relaties

• gaat over
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: IGJ 1.2.3
2# Parameters: $(peildatum)
3# Ontologie: versie 2.0.1 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
12
13SELECT ?kwalificatieniveau (COUNT (DISTINCT ?medewerker) AS ?aantal_medewerkers)
14{
15    BIND ($(peildatum) AS ?peildatum)
16    ?overeenkomst
17        onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ;
18        onz-pers:heeftOpdrachtnemer ?medewerker ;
19        onz-g:isAbout ?functie ;
20        onz-g:startDatum ?start_overeenkomst .
21        OPTIONAL {?overeenkomst onz-g:eindDatum ?eind_overeenkomst}
22        FILTER (?start_overeenkomst <= ?peildatum && ((?eind_overeenkomst >= ?peildatum)||(!BOUND(?eind_overeenkomst))))
23    ?medewerker
24        a onz-g:Human .
25    ?functie a/onz-g:hasQuality/onz-g:hasQualityValue ?functie_niveau ;
26        onz-g:startDatum ?start_functie.
27        OPTIONAL {?functie onz-g:eindDatum ?eind_functie}
28        FILTER (?start_functie <= ?peildatum && ((?eind_functie >= ?peildatum)||(!BOUND(?eind_functie))))
29    ?functie_niveau 
30        a onz-pers:ODBKwalificatieWaarde .
31    {
32        ?functie_niveau
33            rdfs:label ?kwalificatieniveau .
34    } UNION {
35        BIND ('Totaal' AS ?kwalificatieniveau)
36    }
37}
38GROUP BY ?kwalificatieniveau
39ORDER BY ?kwalificatieniveau