1.2.1 Gemiddeld aantal ingezette FTE personeel in loondienst (PIL) met een zorgfunctie.

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• gedefinieerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: NZA Wmg 1.2.1
2# Parameters: ?jaar
3# Ontologie: versie 3.0
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT
12    (COALESCE(ROUND(SUM(?inzet_fte)/COUNT(?maand)), 0) AS ?Teller)
13    ("Niet van toepassing" AS ?Noemer)
14    (COALESCE(ROUND(SUM(?inzet_fte)/COUNT(?maand)), 0) AS ?Indicator_FTE36)
15WHERE {
16    SELECT 
17        ?maand
18        (SUM(?inzet_uren)/141 AS ?inzet_fte)
19    WHERE {
20        # BIND(2024 AS ?jaar) .  # Parameter
21
22        BIND(STRDT(CONCAT(STR(?jaar), "-01-01"), xsd:date) AS ?start_peildatum) .
23        BIND(?start_peildatum + "P1Y"^^xsd:duration - "P1D"^^xsd:duration AS ?eind_peildatum) .
24
25        ?overeenkomst 
26            a onz-pers:ArbeidsOvereenkomst ;
27            onz-pers:heeftOpdrachtnemer ?persoon ;
28            onz-g:hasPart ?overeenkomst_afspraak .
29
30        ?overeenkomst_afspraak
31            a onz-pers:WerkOvereenkomstAfspraak ;
32            onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ;
33            onz-g:startDatum ?start_afspraak .
34        OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
35        FILTER(?start_afspraak <= ?eind_peildatum && ((?eind_afspraak >= ?start_peildatum) || (!BOUND(?eind_afspraak))))
36
37        ?inzet
38            a onz-pers:GewerktePeriode ;
39            onz-g:definedBy ?overeenkomst ;
40            onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
41            onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?inzet_uren .
42        BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet) .
43        FILTER(?start_inzet >= ?start_peildatum && ?start_inzet <= ?eind_peildatum)
44        FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
45        BIND(MONTH(?start_inzet) AS ?maand) .
46    }
47    GROUP BY ?maand
48}