2.1 Aantal cliënten per wet

Concepten

• Forensische indicatiestelling
• Indicatiebesluit
• Mens
• Wlz-indicatie
• Zvw-indicatie

Relaties

• gaat over

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: NZA WMG 2.1
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12    (SUM(?is_zvw) AS ?Aantal_clienten_Zvw)
13    (SUM(?is_wlz) AS ?Aantal_clienten_Wlz)
14    (SUM(?is_fis) AS ?Aantal_clienten_Forensische_zorg)
15    (SUM(?is_overig) AS ?Aantal_clienten_Overige_zorg)
16WHERE {
17    SELECT
18        (MAX(IF(BOUND(?wlz), 1, 0)) AS ?is_wlz)
19        (MAX(IF(BOUND(?zvw), 1, 0)) AS ?is_zvw)
20        (MAX(IF(BOUND(?fis), 1, 0)) AS ?is_fis)
21        (IF(?is_wlz + ?is_zvw + ?is_fis = 0, 1, 0) AS ?is_overig)
22    WHERE {
23        # BIND(2024 AS ?jaar) .  # Parameter
24        
25        BIND(STRDT(CONCAT(STR(?jaar), "-01-01"), xsd:date) AS ?start_datum) .
26        BIND(?start_datum + "P1Y"^^xsd:duration - "P1D"^^xsd:duration AS ?eind_datum)
27        
28        {
29            ?indicatie a onz-zorg:IndicatieBesluit 
30        } UNION {
31            ?indicatie a onz-zorg:ForensischeIndicatieStelling
32        }
33        ?indicatie
34            onz-g:isAbout ?client ;
35            onz-g:startDatum ?start_indicatie .
36        OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie . }
37        FILTER (?start_indicatie <= ?eind_datum && (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?start_datum))
38        
39        ?client a onz-g:Human .
40        OPTIONAL {
41            ?indicatie a onz-zorg:WlzIndicatie .
42            BIND(1 AS ?wlz) .
43        }
44        OPTIONAL {
45            ?indicatie a onz-zorg:ZvwIndicatie .
46            BIND(1 AS ?zvw) .
47        }
48        OPTIONAL {
49            ?indicatie a onz-zorg:ForensischeIndicatieStelling .
50            BIND(1 AS ?fis) .
51        }
52    } GROUP BY ?client
53}
54