Uitwisselprofiel ActiZ Belangenbehartiging

Over Uitwisselprofiel ActiZ Belangenbehartiging

Publicatiedatum:
18-08-2026
Inwerkingtreding:
19-08-2026
Bekijk bron...

1.6. Wat is het aantal cliënten per financieringsstroom?

Concepten

Relaties

Eigenschappen

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Actiz 1.6
2# Parameters: ?jaar, ?kwartaal
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9
10SELECT
11    (?vestiging AS ?Indeling)
12    (IF(?vestiging = "Totaal organisatie", "", SAMPLE(?zk_regio_code)) AS ?Zorgkantoor_regio_code)
13    (COUNT(DISTINCT IF(BOUND(?wlz), ?client, ?unbound)) AS ?Wlz)
14    (COUNT(DISTINCT IF(BOUND(?zvw), ?client, ?unbound)) AS ?Zvw)
15    (COUNT(DISTINCT IF(BOUND(?wmo), ?client, ?unbound)) AS ?Wmo)
16    (COUNT(DISTINCT IF(!BOUND(?zvw) && !BOUND(?wlz) && !BOUND(?wmo), ?client, ?unbound)) AS ?Overig)
17WHERE {
18#    BIND(2024 AS ?jaar)
19#    BIND("Q1" AS ?kwartaal)
20    BIND(
21        IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
22            IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
23                IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
24                    IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
25                        ''))))
26        AS ?peildatum_eerder
27    )
28    BIND(?peildatum_eerder + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?peildatum_later)
29    BIND(IF(?vestiging = "Totaal organisatie", 1, 0) AS ?sortKey)
30
31    {
32        ?indicatie a onz-zorg:IndicatieBesluit
33    } UNION {
34        ?indicatie a onz-zorg:ForensischeIndicatieStelling
35    }
36
37    ?indicatie
38        onz-g:isAbout ?client ;
39        onz-g:startDatum ?start_indicatie .
40    OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie . }
41
42    FILTER (
43        ?start_indicatie <= ?peildatum_later &&
44        (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?peildatum_eerder)
45    )
46
47    ?client a onz-g:Human .
48
49    OPTIONAL {
50        ?indicatie a onz-zorg:WlzIndicatie .
51        BIND(1 AS ?wlz) .
52    }
53    OPTIONAL {
54        ?indicatie a onz-zorg:ZvwIndicatie .
55        BIND(1 AS ?zvw) .
56    }
57    OPTIONAL {
58        ?indicatie a onz-zorg:WmoIndicatie .
59        BIND(1 AS ?wmo) .
60    }
61
62    {
63        # Tak 1: per vestiging
64        ?indicatie ^onz-g:definedBy/onz-g:hasPerdurantLocation ?locatie .
65        ?locatie onz-g:partOf* ?vestiging_uri .
66        ?vestiging_uri a onz-org:Vestiging ;
67            onz-g:identifiedBy ?vest_nr ;
68            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
69        ?vest_nr a onz-org:Vestigingsnummer ;
70            onz-g:hasDataValue ?vestiging .
71
72        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
73        ?pc_gebied onz-g:identifiedBy ?postcode ;
74            onz-g:partOf+ ?zk_regio .
75        ?zk_regio a onz-org:ZorgkantoorRegio .
76    } UNION {
77        # Tak 2: totaal organisatie
78        BIND("Totaal organisatie" AS ?vestiging)
79    }
80
81    BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
82}
83GROUP BY ?vestiging ?sortKey
84ORDER BY ?sortKey ?vestiging
85
Terug naar: 1.5. Wat is het aantal cliënten met crisiszorg?