24.3 Overig - wat is de verhouding tussen kort en lang vreemd vermogen?

Concepten

• EindSaldo
• Grootboekpost
• Grootboekrekening
• Grootboekrubriek

Relaties

• deel van
• gaat over

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 24.3.0
2# Parameters: ?peildatum
3# Ontologie: versie 3.0.0 of nieuwer
4#
5PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8
9SELECT ?Kental ?Waarde
10WHERE {
11    {
12        SELECT (IF(SUM(IF(?jaarrekeningpost = "F Langlopende schulden", ?bedrag, 0)) = 0,
13                "Ongedefinieerd"^^xsd:string,
14                ROUND(SUM(IF(?jaarrekeningpost = "G Kortlopende schulden", ?bedrag, 0)) / 
15                SUM(IF(?jaarrekeningpost = "F Langlopende schulden", ?bedrag, 0)) * 100) / 100) AS ?kvvtovlvv)
16        WHERE {
17            {
18                SELECT ?jaarrekeningpost (SUM(?bedrag_rubriek) AS ?bedrag)
19                WHERE {
20                    {
21                        SELECT ?rubriek ?categorie ((SUM(?geld_bedrag) + SUM(?saldo_waarde) / COUNT(?saldo_waarde)) AS ?bedrag_rubriek)
22                        WHERE {
23                            # BIND("2024-12-31"^^xsd:date AS ?peildatum)
24                            BIND(?peildatum AS ?peildatum_argument)
25
26                            # Selecteer rubrieken: zowel Prismant (Grootboekrubriek) als RGS (Grootboekrekening)
27                            {
28                                { ?rubriek a onz-fin:Grootboekrubriek }
29                                UNION
30                                { ?rubriek a onz-fin:Grootboekrekening }
31                            }
32                            FILTER(STRSTARTS(STR(?rubriek), STR(onz-fin:)))
33                            BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
34
35                            # Categorie-toewijzing op basis van rubriekcode
36                            # Prismant: 14/15 → G, 07 → F
37                            # RGS: BSch → G, BLas → F
38                            BIND(
39                                COALESCE(
40                                    IF(STRSTARTS(?rubriekCode, "14") || STRSTARTS(?rubriekCode, "15"), "G", ?unbound),
41                                    IF(STRSTARTS(?rubriekCode, "07"), "F", ?unbound),
42                                    IF(?rubriekCode = "BSch", "G", ?unbound),
43                                    IF(?rubriekCode = "BLas", "F", ?unbound),
44                                    "other"
45                                ) AS ?categorie
46                            )
47                            
48                            # Meest recente eindsaldo per rubriek
49                            OPTIONAL {
50                                ?rubriek onz-g:isAbout ?saldo .
51                                ?saldo a onz-fin:EindSaldo ;
52                                       onz-fin:heeftGeldBedrag ?saldo_bedrag ;
53                                       onz-g:hasDate ?saldo_datum .
54                                FILTER(?saldo_datum <= ?peildatum_argument)
55                            }
56                            FILTER NOT EXISTS {
57                                ?rubriek onz-g:isAbout ?otherSaldo .
58                                ?otherSaldo a onz-fin:EindSaldo ;
59                                            onz-g:hasDate ?otherDatum .
60                                FILTER(
61                                    ?otherSaldo != ?saldo
62                                    && ?otherDatum <= ?peildatum_argument
63                                    && ?otherDatum > ?saldo_datum
64                                )
65                            }
66                            BIND(IF(BOUND(?saldo_bedrag), ?saldo_bedrag, 0) AS ?saldo_waarde)
67
68                            # Grootboekposten na saldo
69                            OPTIONAL {
70                                ?grootboek_post a onz-fin:Grootboekpost ;
71                                      onz-g:partOf ?rubriek ;
72                                      onz-g:hasDate ?datum ;
73                                      onz-fin:heeftGeldBedrag ?geld_bedrag_temp .
74                                # Anti-dubbeltelling: houd alleen het bladniveau (geen transitive ancestors)
75                                FILTER NOT EXISTS {
76                                    ?grootboek_post onz-g:partOf ?child .
77                                    ?child onz-g:partOf ?rubriek .
78                                    FILTER(?child != ?rubriek)
79                                    { { ?child a onz-fin:Grootboekrekening } UNION { ?child a onz-fin:Grootboekrubriek } }
80                                }
81                                FILTER(
82                                    ?datum <= ?peildatum_argument
83                                    && (!BOUND(?saldo_datum) || ?datum > ?saldo_datum)
84                                )
85                            }
86                            BIND(IF(BOUND(?geld_bedrag_temp), ?geld_bedrag_temp, 0) AS ?geld_bedrag)
87                        }
88                        GROUP BY ?rubriek ?categorie
89                    }
90
91                    VALUES (?categorie ?jaarrekeningpost) {
92                        ("G" "G Kortlopende schulden")
93                        ("F" "F Langlopende schulden")
94                    }
95                } GROUP BY ?jaarrekeningpost
96            }
97        }
98    }
99    
100    BIND("Kort vreemd vermogen t.o.v. lang vreemd vermogen" AS ?Kental)
101    BIND(?kvvtovlvv AS ?Waarde)
102}
103ORDER BY ?Kental