24.9 Overig - wat is verhouding tussen uitbesteed werk en vast personeel?

Concepten

• Grootboekpost
• Grootboekrekening
• Grootboekrubriek

Relaties

• deel van

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 24.9
2# Parameters: ?startperiode, ?eindperiode
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8
9SELECT
10  ("Uitbesteed werk vs vast personeel" AS ?Kental)
11      (IF(
12      BOUND(?vastpersoneel) && (?vastpersoneel != 0),
13      ROUND((COALESCE(?q_ii, 0) / xsd:decimal(?vastpersoneel)) * 100) / 100,
14      "Ongedefinieerd"
15    ) AS ?Waarde
16  )
17WHERE {
18
19  # DEEL 1: Vast personeel = Q.III + Q.IV + Q.V
20  # Prismant: 411-419 (Q.III), 420/4221/4223-4225/4229 (Q.IV), 4226 (Q.V)
21  # RGS: WPer (omvat WPerSol=Q.IV en WPerPen=Q.V, rest=Q.III)
22  {
23    SELECT (SUM(?q_vastpersoneel) AS ?vastpersoneel)
24    WHERE {
25            #  BIND("2024-01-01"^^xsd:date AS ?startperiode)
26            #  BIND("2024-12-31"^^xsd:date AS ?eindperiode)
27
28        ?grootboek_post a onz-fin:Grootboekpost ;
29            onz-g:partOf ?rubriek ;
30            onz-g:hasDate ?datum ;
31            onz-fin:heeftGeldBedrag ?geld_bedrag .
32
33        # Match directe ouder: Grootboekrekening (RGS) of Grootboekrubriek (Prismant)
34        {
35            { ?rubriek a onz-fin:Grootboekrekening }
36            UNION
37            { ?rubriek a onz-fin:Grootboekrubriek }
38        }
39        # Anti-dubbeltelling: houd alleen het bladniveau (geen transitive ancestors)
40        FILTER NOT EXISTS {
41            ?grootboek_post onz-g:partOf ?child .
42            ?child onz-g:partOf ?rubriek .
43            FILTER(?child != ?rubriek)
44            { { ?child a onz-fin:Grootboekrekening } UNION { ?child a onz-fin:Grootboekrubriek } }
45        }
46        FILTER(STRSTARTS(STR(?rubriek), STR(onz-fin:)))
47        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
48
49        FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
50
51        # Vast personeel: Q.III + Q.IV + Q.V
52        BIND(
53          IF(
54            STRSTARTS(?rubriekCode, "411") ||
55            STRSTARTS(?rubriekCode, "412") ||
56            STRSTARTS(?rubriekCode, "413") ||
57            STRSTARTS(?rubriekCode, "414") ||
58            STRSTARTS(?rubriekCode, "415") ||
59            STRSTARTS(?rubriekCode, "416") ||
60            STRSTARTS(?rubriekCode, "419") ||
61            STRSTARTS(?rubriekCode, "420") ||
62            STRSTARTS(?rubriekCode, "4221") ||
63            STRSTARTS(?rubriekCode, "4223") ||
64            STRSTARTS(?rubriekCode, "4224") ||
65            STRSTARTS(?rubriekCode, "4225") ||
66            STRSTARTS(?rubriekCode, "4229") ||
67            STRSTARTS(?rubriekCode, "4226") ||
68            STRSTARTS(?rubriekCode, "WPer"),
69            ?geld_bedrag, 0) AS ?q_vastpersoneel
70        )
71    }
72  }
73
74  # DEEL 2: Q.II Kosten uitbesteed werk en andere externe kosten
75  # Prismant: 417/418
76  # RGS: WKprKuw
77  {
78    SELECT (SUM(?q_ii_bedrag) AS ?q_ii)
79    WHERE {
80            #  BIND("2024-01-01"^^xsd:date AS ?startperiode)
81            #  BIND("2024-12-31"^^xsd:date AS ?eindperiode)
82
83        ?grootboek_post a onz-fin:Grootboekpost ;
84            onz-g:partOf ?rubriek ;
85            onz-g:hasDate ?datum ;
86            onz-fin:heeftGeldBedrag ?geld_bedrag .
87
88        # Match directe ouder: Grootboekrekening (RGS) of Grootboekrubriek (Prismant)
89        {
90            { ?rubriek a onz-fin:Grootboekrekening }
91            UNION
92            { ?rubriek a onz-fin:Grootboekrubriek }
93        }
94        # Anti-dubbeltelling: houd alleen het bladniveau (geen transitive ancestors)
95        FILTER NOT EXISTS {
96            ?grootboek_post onz-g:partOf ?child .
97            ?child onz-g:partOf ?rubriek .
98            FILTER(?child != ?rubriek)
99            { { ?child a onz-fin:Grootboekrekening } UNION { ?child a onz-fin:Grootboekrubriek } }
100        }
101        FILTER(STRSTARTS(STR(?rubriek), STR(onz-fin:)))
102        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
103
104        FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
105
106        # Q.II
107        BIND(
108          IF(
109            STRSTARTS(?rubriekCode, "417") ||
110            STRSTARTS(?rubriekCode, "418") ||
111            STRSTARTS(?rubriekCode, "WKprKuw"),
112            ?geld_bedrag, 0) AS ?q_ii_bedrag
113        )
114    }
115  }
116}
117ORDER BY ?Kental
118