7 Wat zijn de overige kosten van uitbesteed werk (niet-zorg) en andere externe kosten?

Concepten

• Grootboekpost
• Grootboekrekening
• Grootboekrubriek

Relaties

• deel van

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
3PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
4
5# Indicator: Nza Kostprijs 7
6# Canonical id: MONO-0018 - "Wat zijn de overige kosten van uitbesteed werk (niet-zorg) en andere externe kosten?"
7# Parameters: ?meetperiode
8# Ontologie: versie 3.0.0 of nieuwer
9# Vereist uitgebreide financiele dataset en RGS-zorg versie om te testen
10
11SELECT
12("Totaal organisatie" AS ?Indeling)
13("Totaal jaar" AS ?Periode)
14(IF(COUNT(?geld_bedrag_post) = 0, "Niet beschikbaar", (ROUND(SUM(?geld_bedrag_post) * 100) / 100)) AS ?Bedrag)
15WHERE {
16
17    # BIND("2024-01-01"^^xsd:date AS ?startperiode)
18    # BIND("2024-12-31"^^xsd:date AS ?eindperiode)
19
20    # >>> START BB: BB-011_grootboekpost_rubriek.rq
21    ?grootboekpost
22    a onz-fin:Grootboekpost ;
23    onz-fin:heeftGeldBedrag ?geld_bedrag_post ;
24    onz-g:hasDate ?boekingsdatum ;
25    onz-g:partOf ?rubriek .
26
27    # Behoud de grootboekpost alleen voor de meest specifieke rubriek,
28    # om eventuele dubbeltelling door de hiërarchische structuur rubriekcodes te voorkomen
29    FILTER NOT EXISTS {
30        ?grootboekpost onz-g:partOf ?specifiekereRubriek .
31        ?specifiekereRubriek onz-g:partOf+ ?rubriek .
32    }
33    # <<< END BB: BB-011_grootboekpost_rubriek.rq
34
35    # >>> START BB: BB-007_geldig_binnen_periode.rq
36    FILTER(?boekingsdatum >= ?startperiode && ?boekingsdatum <= ?eindperiode)
37    # <<< END BB: BB-007_geldig_binnen_periode.rq
38
39    # Vind de juiste rubrieken voor Prismant en RGS
40    {
41
42        # >>> START BB: BB-010_rubriek_rubriekcode.rq
43        VALUES ?rubriekType { onz-fin:Grootboekrubriek onz-fin:Grootboekrekening }
44        ?rubriek a ?rubriekType .
45        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
46        # <<< END BB: BB-010_rubriek_rubriekcode.rq
47
48        # >>> START BB: BB-008_zorgkostenmapping_Prismant.rq
49        VALUES (?mappingPrefix ?kostenSoort) {
50            ("468000" "Kosten van activiteiten buiten de instelling")
51        }
52        # <<< END BB: BB-008_zorgkostenmapping_Prismant.rq
53
54        # >>> START BB: BB-015_rubriekcode_mappingprefix.rq
55        FILTER(STRSTARTS(?rubriekCode, ?mappingPrefix))
56        # <<< END BB: BB-015_rubriekcode_mappingprefix.rq
57
58    }
59    UNION
60    {
61
62        # >>> START BB: BB-010_rubriek_rubriekcode.rq
63        VALUES ?rubriekType { onz-fin:Grootboekrubriek onz-fin:Grootboekrekening }
64        ?rubriek a ?rubriekType .
65        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
66        # <<< END BB: BB-010_rubriek_rubriekcode.rq
67
68        # >>> START BB: BB-009_zorgkostenmapping_RGS_zorg_3_8.rq
69        VALUES (?rubriekCodeRGS ?kostenSoort) {
70            ("WKprKuwAek" "Andere externe kosten")
71            ("WKprKuwOnc" "Overige kosten uitbesteed werk (niet-zorg) en andere externe kosten (CBS)")
72            ("WKprKuwDfw" "Doorberekend / Overboeking ivm functionele indeling kosten uitbesteed werk en andere externe kosten")
73        }
74        # <<< END BB: BB-009_zorgkostenmapping_RGS_zorg_3_8.rq
75
76        # >>> START BB: BB-015_rubriekcode_mappingprefix.rq
77        FILTER(STRSTARTS(?rubriekCode, ?rubriekCodeRGS))
78        # <<< END BB: BB-015_rubriekcode_mappingprefix.rq
79
80    }
81
82}
83