14.1 Wat is het aantal cliënten per zorgprofiel en vestiging?

Concepten

• Mens
• Verpleegproces
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• VV Beschermd verblijf met intensieve palliatief-terminale zorg
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 14.1
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4PREFIX onz-g: <http://purl.org/ozo/onz-g#>
5PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT 
12    (?vestiging AS ?Indeling)
13    (?zorgprofiel AS ?Zorgprofiel)
14    (COUNT(DISTINCT(?client)) AS ?Indicator)
15WHERE
16{ 
17    #BIND("2024-01-01"^^xsd:date AS ?peildatum)
18    VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
19
20    # Gedeeld patroon: zorgproces + indicatie + client
21    ?zorgproces
22        a onz-zorg:NursingProcess ;
23        onz-g:definedBy ?indicatie ;
24        onz-g:startDatum ?start_zorgproces .
25    OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
26    FILTER (?start_zorgproces <= ?peildatum && 
27            ((?eind_zorgproces >= ?peildatum) || (!BOUND(?eind_zorgproces))))
28
29    ?indicatie a onz-zorg:WlzIndicatie ;
30        onz-g:hasPart ?zorgprofiel ;
31        onz-g:isAbout ?client ;
32        onz-g:startDatum ?ind_start .
33    OPTIONAL { ?indicatie onz-g:eindDatum ?ind_eind }
34    FILTER (?ind_start <= ?peildatum &&
35            ((?ind_eind >= ?peildatum) || (!BOUND(?ind_eind))))
36    ?client a onz-g:Human .
37
38    {
39        # Per vestiging
40        ?zorgproces onz-g:hasPerdurantLocation ?locatie .
41        ?locatie onz-g:partOf* ?vestiging_uri .
42        ?vestiging_uri a onz-org:Vestiging ;
43            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6;
44            onz-g:identifiedBy ?vest_nr . 
45        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
46        ?pc_gebied 
47            onz-g:identifiedBy ?postcode ;
48            onz-g:partOf+ ?zk_regio .
49        ?zk_regio a onz-org:ZorgkantoorRegio .
50        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
51        ?vest_nr a onz-org:Vestigingsnummer ;
52            onz-g:hasDataValue ?vestiging .
53    }
54    UNION
55    {
56        # Totaal organisatie (inclusief zorgprocessen zonder locatie)
57        BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
58    }
59} 
60GROUP BY ?vestiging ?zorgprofiel 
61ORDER BY ?vestiging ?zorgprofiel