15.4.5 Wat is het gedeclareerd bedrag per zorgsector?

Concepten

• Wlz-indicatie
• ZorgDeclaratie
• ZorgEnVerpleegProces

Relaties

• gaat over
• gedefinieerd door
• heeft deel

Eigenschappen

• goedgekeurd
• heeft datum
• heeftGeldBedrag

Instanties

• Sector GGZ, B-groep
• Sector GGZ, Wonen
• Sector Lichamelijk gehandicapt
• Sector Licht verstandelijk gehandicapt
• Sector Verpleging en verzorging
• Sector Verstandelijk gehandicapt
• Sector Zintuiglijk gehandicapt, auditief en communicatief
• Sector Zintuiglijk gehandicapt, visueel

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.5
2# Parameters: ?startperiode, ?eindperiode
3# Ontologie: versie 3.0.0
4
5PREFIX onz-g:     <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg:  <http://purl.org/ozo/onz-zorg#>
7PREFIX xsd:       <http://www.w3.org/2001/XMLSchema#>
8PREFIX onz-org:   <http://purl.org/ozo/onz-org#>
9PREFIX rdfs:      <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
11
12
13SELECT 
14    ("Totaal organisatie" AS ?Indeling)
15    ((ROUND(SUM(?ggzWAmount) / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_GGZ_W)
16    ((ROUND(SUM(?ggzBAmount) / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_GGZ_B)
17    ((ROUND(SUM(?lgAmount)   / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_LG)
18    ((ROUND(SUM(?lvgAmount)  / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_LVG)
19    ((ROUND(SUM(?vgAmount)   / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_VG)
20    ((ROUND(SUM(?zgaudAmount)/ SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_ZGAUD)
21    ((ROUND(SUM(?zgvisAmount)/ SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_ZGVIS)
22    ((ROUND(SUM(?vvAmount)   / SUM(?amount) * 10000) / 100.0) AS ?Procent_gedeclareerd_bedrag_VV)
23WHERE {
24    #BIND("2024-01-01"^^xsd:date AS ?startperiode)
25    #BIND("2024-12-31"^^xsd:date AS ?eindperiode)
26
27    ?declaratie
28        a onz-g:CareInvoice ;
29        onz-g:hasDate ?date ;
30        onz-g:goedgekeurd "true"^^xsd:boolean ;
31        onz-fin:heeftGeldBedrag ?amount ;
32        onz-g:isAbout ?zorgproces .
33
34    FILTER(?startperiode <= ?date && ?date <= ?eindperiode)
35
36    ?zorgproces
37        a onz-g:CureAndCareProcess ;
38        onz-g:definedBy ?indicatie .
39
40    ?indicatie
41        a onz-zorg:WlzIndicatie ;
42    	onz-g:hasPart/onz-g:isAbout ?sector .
43
44    # Per sectorbedrag
45    BIND(IF(?sector = onz-zorg:GGZ-W, ?amount, 0) AS ?ggzWAmount)
46    BIND(IF(?sector = onz-zorg:GGZ-B, ?amount, 0) AS ?ggzBAmount)
47    BIND(IF(?sector = onz-zorg:LG,     ?amount, 0) AS ?lgAmount)
48    BIND(IF(?sector = onz-zorg:LVG,    ?amount, 0) AS ?lvgAmount)
49    BIND(IF(?sector = onz-zorg:VG,     ?amount, 0) AS ?vgAmount)
50    BIND(IF(?sector = onz-zorg:ZGAUD,  ?amount, 0) AS ?zgaudAmount)
51    BIND(IF(?sector = onz-zorg:ZGVIS,  ?amount, 0) AS ?zgvisAmount)
52    BIND(IF(?sector = onz-zorg:VV,     ?amount, 0) AS ?vvAmount)
53}
54