15.4.2 Hoeveel Wlz-cliënten zijn er per sector?

Concepten

• Langdurige zorg sector
• Mens
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• ZorgEnVerpleegProces
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• Sector GGZ, B-groep
• Sector GGZ, Wonen
• Sector Lichamelijk gehandicapt
• Sector Licht verstandelijk gehandicapt
• Sector Verpleging en verzorging
• Sector Verstandelijk gehandicapt
• Sector Zintuiglijk gehandicapt, auditief en communicatief
• Sector Zintuiglijk gehandicapt, visueel

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.2
2# Parameters: ?peildatum ?zorgkantoor 
3# Ontologie: versie 2.0.0 of nieuwer
4
5
6PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-g: <http://purl.org/ozo/onz-g#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
11PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
12
13SELECT 
14	(?vestiging AS ?Indeling)        
15    (COUNT(DISTINCT IF(?sector = onz-zorg:VV, ?client, ?unbound)) AS ?VV)
16    (COUNT(DISTINCT IF(?sector = onz-zorg:LG, ?client, ?unbound)) AS ?LG)
17    (COUNT(DISTINCT IF(?sector = onz-zorg:LVG, ?client, ?unbound)) AS ?LVG)
18    (COUNT(DISTINCT IF(?sector = onz-zorg:VG, ?client, ?unbound)) AS ?VG)
19    (COUNT(DISTINCT IF(?sector = onz-zorg:ZGAUD, ?client, ?unbound)) AS ?ZGAUD)
20    (COUNT(DISTINCT IF(?sector = onz-zorg:ZGVIS, ?client, ?unbound)) AS ?ZGVIS)
21    (COUNT(DISTINCT IF(?sector = onz-zorg:GGZ-B, ?client, ?unbound)) AS ?GGZ_B)
22    (COUNT(DISTINCT IF(?sector = onz-zorg:GGZ-W, ?client, ?unbound)) AS ?GGZ_W)
23WHERE
24{
25	# BIND ("2024-01-01"^^xsd:date AS ?peildatum)  # Test parameter
26
27    ?sector a onz-zorg:LangdurigeZorgSector .
28    
29    # Gedeeld patroon: zorgproces + indicatie + client
30    ?zorgproces 
31        a onz-g:CureAndCareProcess ;
32        onz-g:definedBy ?indicatie ;
33        onz-g:startDatum ?start_zorgproces .
34    OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
35    
36    FILTER(?start_zorgproces <= ?peildatum && ( !BOUND(?eind_zorgproces) || ?eind_zorgproces >= ?peildatum ))
37    ?indicatie
38        a onz-zorg:WlzIndicatie ;
39        onz-g:isAbout ?client ;
40        onz-g:hasPart/onz-g:isAbout ?sector ;
41        onz-g:startDatum ?start_indicatie .
42    OPTIONAL {?indicatie onz-g:eindDatum ?eind_indicatie}
43    FILTER (?start_indicatie <= ?peildatum && (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?peildatum))
44    
45    ?client a onz-g:Human .
46    
47    {
48        # Per vestiging
49        ?zorgproces onz-g:hasPerdurantLocation ?locatie .
50        ?locatie onz-g:partOf* ?vestiging_uri .
51        ?vestiging_uri 
52            a onz-org:Vestiging ;
53            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6;
54            onz-g:identifiedBy ?vest_nr . 
55        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
56        ?pc_gebied 
57            onz-g:identifiedBy ?postcode ;
58            onz-g:partOf+ ?zk_regio .
59        ?zk_regio a onz-org:ZorgkantoorRegio .
60        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
61        ?vest_nr 
62            a onz-org:Vestigingsnummer ;
63            onz-g:hasDataValue ?vestiging .
64    }
65    UNION
66    {
67        # Totaal organisatie (inclusief zorgprocessen zonder locatie)
68        BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
69    }
70}
71GROUP BY ?vestiging
72ORDER BY ?vestiging
73