15.4.3 Hoeveel Wlz-cliënten met zorgprofiel VV zijn er per leveringsvorm?

Concepten

• Langdurige zorg sector
• Leveringsvorm
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Wlz-indicatie
• ZorgEnVerpleegProces
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• Modulair pakket thuis
• Persoonsgebonden budget
• Verblijf in een instelling
• Volledig pakket thuis

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.3
2# Parameters: ?peildatum ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
9
10SELECT
11    (?Organisatieonderdeel AS ?Indeling)
12    (SUM(IF(?lv = onz-zorg:instelling, 1, 0)) AS ?Verblijf)
13    (SUM(IF(?lv = onz-zorg:vpt, 1, 0)) AS ?VPT)
14    (SUM(IF(?lv = onz-zorg:mpt, 1, 0)) AS ?MPT)
15    (SUM(IF(?lv = onz-zorg:pgb, 1, 0)) AS ?PGB)
16
17WHERE {
18    # Deze binnenste query zorgt ervoor dat alleen unieke clienten per organisatieonderdeel en leveringsvorm in de results komen en zo dus dat klanten met dubbele indicaties van dezelfde sector niet dubbel worden geteld in de summatie hierboven
19    SELECT DISTINCT
20        ?Organisatieonderdeel
21        ?client
22        ?lv
23    WHERE {
24
25        # BIND("2024-01-01"^^xsd:date AS ?peildatum)  # Test parameter
26
27        # Gedeeld patroon: zorgproces + indicatie + client
28        ?zorgproces
29            a onz-g:CureAndCareProcess ;
30            onz-g:definedBy ?indicatie ;
31            onz-g:startDatum ?start_zorgproces .
32        OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
33        FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum) || (!BOUND(?eind_zorgproces))))
34
35        ?indicatie
36            a onz-zorg:WlzIndicatie ;
37            onz-g:hasPart/onz-g:isAbout ?sector ;
38            onz-g:hasPart ?lv ;
39            onz-g:isAbout ?client ;
40            onz-g:startDatum ?ind_start .
41        OPTIONAL { ?indicatie onz-g:eindDatum ?ind_eind }
42        FILTER (?ind_start <= ?peildatum && ((?ind_eind >= ?peildatum) || (!BOUND(?ind_eind))))
43
44        ?sector a onz-zorg:LangdurigeZorgSector .
45        FILTER(?sector = onz-zorg:VV)
46        ?lv a onz-zorg:Leveringsvorm .
47        ?client a onz-g:Human .
48
49        {
50            # Per vestiging
51            ?zorgproces onz-g:hasPerdurantLocation ?locatie .
52            ?locatie
53                a onz-g:StationaryArtifact ;
54                onz-g:partOf* ?vestiging_uri .
55            ?vestiging_uri a onz-org:Vestiging ;
56                onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 ;
57                onz-g:identifiedBy ?vest_nr .
58            BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
59            ?pc_gebied
60                onz-g:identifiedBy ?postcode ;
61                onz-g:partOf+ ?zk_regio .
62            ?zk_regio a onz-org:ZorgkantoorRegio .
63            ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
64            ?vest_nr a onz-org:Vestigingsnummer ;
65                onz-g:hasDataValue ?vestiging .
66            BIND(?vestiging AS ?Organisatieonderdeel)
67        }
68        UNION
69        {
70            # Totaal organisatie (inclusief zorgprocessen zonder locatie)
71            BIND("Organisatie (gecontracteerd + algemeen)" AS ?Organisatieonderdeel)
72        }
73    }
74}
75GROUP BY ?Organisatieonderdeel
76