2.2 Hoeveel uur zijn er verloond?

Concepten

• Arbeidsovereenkomst
• Functie in organisatie-rol
• Onverplaatsbaar artefact
• Verloonde periode
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 2.2
2# Parameters: ?jaar, ?kwartaal, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
10
11SELECT
12	(?vestiging AS ?Organisatieindeling)
13	(SUM(?verloonde_uren * ?zorg) AS ?Zorggerelateerd)
14	(SUM(?verloonde_uren * ?niet_zorg) AS ?Niet_Zorggerelateerd)
15    (?Zorggerelateerd + ?Niet_Zorggerelateerd AS ?Totaal)
16
17{
18    # BIND(2023 AS ?jaar)
19    # BIND("Q3" AS ?kwartaal)
20    # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
21    BIND(IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
22        IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
23        IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
24        IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
25        '')))) AS ?start_periode)
26    BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
27    
28    # Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
29    ?overeenkomst 
30        a onz-pers:ArbeidsOvereenkomst ;
31        onz-pers:heeftOpdrachtnemer ?persoon ;
32        onz-g:hasPart ?overeenkomst_afspraak .
33    ?overeenkomst_afspraak
34        a onz-pers:WerkOvereenkomstAfspraak ;
35        onz-g:startDatum ?start_afspraak .
36    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
37    FILTER(?start_afspraak <= ?eind_periode && ((?eind_afspraak >= ?start_periode) || (!BOUND(?eind_afspraak))))
38
39    ?overeenkomst_afspraak onz-g:isAbout ?functie .                
40    ?functie a onz-g:OccupationalPositionRole .
41    
42    ?verloonde_periode
43        a onz-fin:VerloondePeriode ;
44        onz-g:definedBy ?overeenkomst ;
45        onz-g:startDatum ?datum_verloonde_periode ;
46        onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?verloonde_uren .
47    FILTER(?datum_verloonde_periode >= ?start_periode && ?datum_verloonde_periode <= ?eind_periode)
48    FILTER(?datum_verloonde_periode >= ?start_afspraak && (?datum_verloonde_periode <= ?eind_afspraak || !BOUND(?eind_afspraak)))
49
50    {   
51        ?overeenkomst_afspraak onz-g:isAbout ?locatie .
52    	?locatie a onz-g:StationaryArtifact ;
53        	onz-g:partOf* ?vestiging_uri .
54        ?vestiging_uri a onz-org:Vestiging ;
55            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
56        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
57        ?pc_gebied 
58            onz-g:identifiedBy ?postcode ;
59            onz-g:partOf+ ?zk_regio .
60        ?zk_regio a onz-org:ZorgkantoorRegio .
61        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
62        ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
63        ?vest_nr a onz-org:Vestigingsnummer ;
64            onz-g:hasDataValue ?vestiging .
65    } UNION {
66        BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
67    }
68    # Bepaal of de functie op de overeenkomst van het type ZorgverlenerFunctie is
69    BIND(IF(EXISTS{?functie a onz-pers:ZorgverlenerFunctie}, 1, 0) AS ?zorg)
70    BIND(IF(?zorg = 0, 1, 0) AS ?niet_zorg)
71
72}
73GROUP BY ?vestiging