8.1 Welk deel van de ingezette uren personeel is door PNIL?

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• Inhuurovereenkomst
• Onverplaatsbaar artefact
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• heeft perdurantlocatie
• opereert in regio

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 8.1
2# Parameters: ?jaar, ?kwartaal, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT 
12    (?vestiging AS ?Indeling)
13    (SUM(?uren * ?pnil) AS ?Ingezette_uren_PNIL)
14    (SUM(?uren * ?pil) AS ?Ingezette_uren_PIL)
15    (100*SUM(?uren * ?pnil)/SUM(?uren) AS ?Procent_ingezette_uren_PNIL)
16{
17    #  BIND(2023 AS ?jaar)
18    #  BIND("Q3" AS ?kwartaal)
19    #  BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
20    
21    BIND(IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
22        IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
23        IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
24        IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
25        '')))) AS ?start_periode)
26    BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
27
28    VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomst onz-pers:InhuurOvereenkomst onz-pers:UitzendOvereenkomst}
29    
30    ?overeenkomst 
31        a ?type_overeenkomst ;
32        onz-pers:heeftOpdrachtnemer ?persoon ;
33        onz-g:hasPart ?overeenkomst_afspraak .
34    ?overeenkomst_afspraak
35        a onz-pers:WerkOvereenkomstAfspraak ;
36        onz-g:startDatum ?start_afspraak .
37    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
38    FILTER(?start_afspraak <= ?eind_periode && ((?eind_afspraak >= ?start_periode) || (!BOUND(?eind_afspraak))))
39    OPTIONAL {
40        ?overeenkomst_afspraak onz-g:isAbout ?locatie_afspraak .
41        ?locatie_afspraak a onz-g:StationaryArtifact .
42    }
43
44    ?inzet
45        a onz-pers:GewerktePeriode ;
46        onz-g:definedBy ?overeenkomst ;
47        onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
48        onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?uren .
49    OPTIONAL{ ?inzet onz-g:hasPerdurantLocation ?locatie_werk }
50    BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
51    FILTER(?start_inzet >= ?start_periode && ?start_inzet <= ?eind_periode)
52    FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
53
54    BIND(IF(!BOUND(?locatie_werk), ?locatie_afspraak, ?locatie_werk) AS ?locatie)
55            
56    {     
57        # COALESCE i.p.v. FILTER(BOUND): voorkomt dat Fuseki partOf* evalueert met ongebonden ?locatie
58        BIND(COALESCE(?locatie, <urn:sparql:guard:no-locatie>) AS ?locatie_safe)
59        ?locatie_safe onz-g:partOf* ?vestiging_uri .
60        ?vestiging_uri a onz-org:Vestiging ;
61            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 ;
62            onz-g:identifiedBy ?vest_nr .    	
63        ?vest_nr a onz-org:Vestigingsnummer ;
64            onz-g:hasDataValue ?vestiging .
65        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
66        ?pc_gebied 
67            onz-g:identifiedBy ?postcode ;
68            onz-g:partOf+ ?zk_regio .
69        ?zk_regio a onz-org:ZorgkantoorRegio .
70        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
71    } UNION {
72        # Includeer ook de organisatie als geheel en label deze als vestiging
73        BIND("Organisatie (gecontracteerd + algemeen)" AS ?vestiging)
74    }
75
76  	BIND(IF (?type_overeenkomst = onz-pers:ArbeidsOvereenkomst, 1, 0) AS ?pil)
77    BIND(IF (?pil = 0, 1, 0) AS ?pnil)
78
79}
80GROUP BY ?vestiging 
81ORDER BY ?vestiging