1.1. Aantal personeelsleden op peildatum

Concepten

• Arbeidsovereenkomst
• Bedrijf
• Functie in organisatie-rol
• Inhuurovereenkomst
• Mens
• Oproepovereenkomst
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: VWS 1.1
2# Parameters: $(peildatum)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
12
13SELECT 
14    ?vestiging 
15    (SUM(?zorg_boolean) AS ?Zorg) 
16    (COUNT(?persoon) - SUM(?zorg_boolean) AS ?Niet_zorg)
17    (COUNT(?persoon) AS ?Totaal) 
18{
19    {
20        SELECT ?persoon ?vestiging (MAX(?zorgfunctie) AS ?zorg_boolean)
21        {
22            #Bepaal de peildatum
23            BIND($(peildatum) AS ?peildatum)
24            
25            #Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
26            VALUES ?personeels_overeenkomst 
27      		{ 
28        		onz-pers:ArbeidsOvereenkomst
29        		onz-pers:OproepOvereenkomst
30        		onz-pers:UitzendOvereenkomst
31        		onz-pers:InhuurOvereenkomst
32      		}
33
34            #Selecteer alle personeelsleden (personen met een arbeids-, oproep,- uitzend,- of inhuurovereenkomst) binnen de meetperiode
35            ?persoon
36                a onz-g:Human .
37            ?overeenkomst
38                a ?personeels_overeenkomst ;
39                onz-pers:heeftOpdrachtnemer ?persoon ;
40                onz-g:isAbout ?functie ;
41                onz-g:isAbout ?locatie ;
42                onz-g:startDatum ?start_overeenkomst .
43                OPTIONAL {?overeenkomst a ?personeels_overeenkomst ;
44                        onz-g:eindDatum ?eind_overeenkomst}
45      		    FILTER (?start_overeenkomst <= ?peildatum && ((?eind_overeenkomst >= ?peildatum)||(!BOUND(?eind_overeenkomst))))
46
47            #Bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
48            {
49                ?locatie 
50                    onz-g:partOf* ?vestiging_uri .
51                ?vestiging_uri 
52                    a onz-org:Vestiging ;
53                    onz-g:identifiedBy ?vest_nr .
54                ?vest_nr
55                    a onz-org:Vestigingsnummer ;
56                    onz-g:hasDataValue ?vestiging .
57            } UNION {
58                #Includeer ook de organisatie als geheel en label deze als vestiging
59                ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
60                ?organisatie_uri 
61                    a onz-g:Business ;
62                    rdfs:label ?Organisatie .
63                BIND(CONCAT('Totaal ',?Organisatie) AS ?vestiging)
64            }
65
66            #Bepaal of de functie op de overeenkomst van het type ZorgverlenerFunctie is
67            ?functie 
68                a onz-g:OccupationalPositionRole ;
69                a ?type_functie .
70            BIND(IF(?type_functie = onz-pers:ZorgverlenerFunctie, 1, 0) AS ?zorgfunctie)
71        } 
72        GROUP BY ?persoon ?vestiging
73    }
74} GROUP BY ?vestiging```