1.4. Percentage inzet uitzendkrachten (PNIL)

Concepten

• Arbeidsovereenkomst
• Inhuurovereenkomst
• Oproepovereenkomst
• Uitzendovereenkomst
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• heeftEindTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: VWS 1.4
2# Parameters: $(kwartaal)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT 
13    ?vestiging
14    (SUM(?pil_uren)AS ?pil_uren_tot) 
15    (SUM(?pnil_uren)AS ?pnil_uren_tot) 
16    (((SUM(?pnil_uren)/SUM(?uren))*100) AS ?percentage_pnil)
17WHERE 
18{
19    SELECT DISTINCT 
20        ?vestiging
21        ?gewerkteperiode 
22        ?uren 
23        ?pnil_uren
24        ?pil_uren
25    WHERE 
26    { 
27        # definieer kwartaal waarin overeenkomst geldig moet zijn
28        BIND($(kwartaal) AS ?kwartaal)
29        BIND(
30            IF(?kwartaal = 'Q1', '2022-01-01'^^xsd:date, 
31            IF(?kwartaal = 'Q2', '2022-04-01'^^xsd:date,
32            IF(?kwartaal = 'Q3', '2022-07-01'^^xsd:date,
33            IF(?kwartaal = 'Q4', '2022-10-01'^^xsd:date, 
34            '')))) AS ?start_periode)
35        BIND((?start_periode + "P3M"^^xsd:duration - "P1D"^^xsd:duration) AS ?eind_periode)
36
37        # selecteer overeenkomst met start en eind
38        ?overeenkomst 
39            onz-g:startDatum ?start_overeenkomst ;
40        	onz-g:isAbout ?locatie .         
41        OPTIONAL {?overeenkomst onz-g:eindDatum ?eind_overeenkomst}
42        FILTER(?start_overeenkomst <= ?eind_periode && ((?eind_overeenkomst >= ?start_periode) || (!BOUND(?eind_overeenkomst))))
43
44        # selecteer de vestiging per overeenkomst
45        ?locatie onz-g:partOf* ?vestiging_uri .
46        ?locatie 
47            onz-g:partOf* ?vestiging_uri .
48        ?vestiging_uri 
49            a onz-org:Vestiging ;
50            onz-g:identifiedBy ?vest_nr .
51        ?vest_nr
52            a onz-org:Vestigingsnummer ;
53            onz-g:hasDataValue ?vestiging .
54
55        # selecteer uren van gewerkte periode
56        ?gewerkteperiode 
57            onz-g:definedBy ?overeenkomst ;
58            onz-g:hasBeginTimeStamp ?start_werkDT ;
59            onz-g:hasEndTimeStamp ?eind_werkDT ;
60            onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?uren ;
61        BIND(STRDT(SUBSTR(STR(?start_werkDT),1,10), xsd:date) AS ?start_werk)
62        BIND(STRDT(SUBSTR(STR(?eind_werkDT),1,10), xsd:date) AS ?eind_werk)
63
64        # filter in gewenste tijsdperiode
65        FILTER(?start_werk >= ?start_periode && ?eind_werk <= ?eind_periode)
66		
67        # filter de gewenste overeenkomsten
68        VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomst onz-pers:InhuurOvereenkomst onz-pers:UitzendOvereenkomst onz-pers:OproepOvereenkomst }
69        ?overeenkomst a ?type_overeenkomst .
70        	
71        # ken PNIL uren toe aan inhuur- en uitzendovereenkomsten
72        BIND(IF(?type_overeenkomst = onz-pers:InhuurOvereenkomst || ?type_overeenkomst = onz-pers:UitzendOvereenkomst, ?uren, 0) AS ?pnil_uren)
73        BIND(IF(?type_overeenkomst = onz-pers:ArbeidsOvereenkomst || ?type_overeenkomst = onz-pers:OproepOvereenkomst, ?uren, 0) AS ?pil_uren)
74    } 
75}
76GROUP BY ?vestiging