1.5. Aantal vrijwilligers

Concepten

• Bedrijf
• Functie in organisatie-rol
• Mens
• Vestiging
• Vestigingsnummer
• Vrijwilligersovereenkomst
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: VWS 1.5
2# Parameters: -
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
12
13SELECT 
14    ?vestiging 
15    (SUM(?zorg_boolean) AS ?Zorg) 
16    (COUNT(?persoon) - SUM(?zorg_boolean) AS ?Niet_zorg)
17    (COUNT(?persoon) AS ?Totaal) 
18{
19    {
20        SELECT ?persoon ?vestiging (MAX(?zorgfunctie) AS ?zorg_boolean)
21        {
22            #Bepaal een meetperiode van drie maanden, startend vanaf een in te vullen datum
23            BIND("2022-01-01"^^xsd:date AS ?start_periode)
24            BIND(?start_periode + "P3M"^^xsd:duration - "P1D"^^xsd:duration AS ?eind_periode)
25            
26            #Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
27            VALUES ?personeels_overeenkomst 
28      		{ 
29        		onz-pers:VrijwilligersOvereenkomst
30      		}
31
32            #Selecteer alle personeelsleden (personen met een arbeids-, oproep,- uitzend,- of inhuurovereenkomst) binnen de meetperiode
33            ?persoon
34                a onz-g:Human ;
35                ^onz-pers:heeftOpdrachtnemer ?overeenkomst .
36            ?overeenkomst
37                a ?personeels_overeenkomst ;
38                onz-g:isAbout ?functie ;
39                onz-g:isAbout ?locatie ;
40                onz-g:startDatum ?start_overeenkomst .
41                OPTIONAL {?overeenkomst onz-g:eindDatum ?eind_overeenkomst}
42                FILTER(?start_overeenkomst <= ?eind_periode && ((?eind_overeenkomst >= ?start_periode) || (!BOUND(?eind_overeenkomst))))
43
44            #Bepaal de vestiging waar de werkzaamheden verricht worden volgens de werkovereenkomst
45            {
46                ?locatie 
47                    onz-g:partOf* ?vestiging_uri .
48                ?vestiging_uri 
49                    a onz-org:Vestiging ;
50                    onz-g:identifiedBy ?vest_nr .
51                ?vest_nr
52                    a onz-org:Vestigingsnummer ;
53                    onz-g:hasDataValue ?vestiging .
54            } UNION {
55                #Includeer ook de organisatie als geheel en label deze als vestiging
56                ?locatie onz-g:partOf*/onz-org:vestigingVan ?organisatie_uri .
57                ?organisatie_uri 
58                    a onz-g:Business ;
59                    rdfs:label ?Organisatie .
60                BIND(CONCAT('Totaal ',?Organisatie) AS ?vestiging)
61            }
62            
63            #Bepaal of de functie op de overeenkomst van het type ZorgverlenerFunctie is
64            ?functie 
65                a onz-g:OccupationalPositionRole ;
66                a ?type_functie .
67            BIND(IF(?type_functie = onz-pers:ZorgverlenerFunctie, 1, 0) AS ?zorgfunctie)
68        } 
69        GROUP BY ?persoon ?vestiging
70    }
71} GROUP BY ?vestiging