5.2. Aantal cliënten per leveringsvorm op peildatum

Concepten

• Leveringsvorm
• Mens
• Verpleegproces
• Vestiging
• Vestigingsnummer

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft perdurantlocatie

Eigenschappen

• einddatum
• heeft datawaarde
• indicatie behandeling
• startdatum

Instanties

• VV Beschermd verblijf met intensieve palliatief-terminale zorg
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging
• Verblijf in een instelling

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: VWS 5.2
2# Parameters: $(peildatum)
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13    ?vestiging
14	?leveringsvorm
15    (COUNT (DISTINCT(?client)) AS ?indicator)
16WHERE
17{ 
18    BIND ($(peildatum) AS ?peildatum)
19    VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
20
21    #selecteer de zorgprocessen op de vestigingen die voldoen aan de inclusiecriteria
22    ?zorgproces
23        a onz-zorg:NursingProcess ;
24        onz-g:definedBy ?indicatie ;
25        onz-g:hasPerdurantLocation ?locatie ;
26        onz-g:startDatum ?start_zorgproces .
27    	OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
28    	FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces))))
29    ?locatie 
30        onz-g:partOf* ?vestiging_uri .
31    ?vestiging_uri 
32        a onz-org:Vestiging ;
33    	onz-g:identifiedBy ?vest_nr .
34    ?vest_nr
35        a onz-org:Vestigingsnummer ;
36        onz-g:hasDataValue ?vestiging .
37    
38    #selecteer de bijbehordene indicatie, om unieke clienten te kunnen bepalen
39    ?indicatie 
40        onz-g:hasPart ?zorgprofiel ;
41        onz-g:hasPart ?lv ;
42        onz-g:isAbout ?client .
43  		OPTIONAL {?indicatie onz-zorg:heeftIndicatieBehandeling ?behandeling}
44        BIND(IF(BOUND(?behandeling), ?behandeling, "false"^^xsd:boolean) AS ?incl_behandeling)
45    ?client a onz-g:Human .
46  	?lv
47    	a onz-zorg:Leveringsvorm ;
48        rdfs:label ?leveringsvorm_label ;
49        BIND(IF(?lv != onz-zorg:instelling, ?leveringsvorm_label, 
50      		IF(?incl_behandeling, "Verblijf met behandeling", "Verblijf zonder behandeling"))
51      		AS ?leveringsvorm)		
52} 
53GROUP BY ?vestiging ?leveringsvorm
54ORDER BY ?vestiging ?leveringsvorm