30. Wat is het aantal leveringen en het gedeclareerde bedrag van Zorg in Natura per combinatie van Wlz-Prestatiecode, tarief en tariefeenheid?

Concepten

• Leveringsvorm
• Wlz-indicatie
• ZorgDeclaratie
• ZorgEnVerpleegProces

Relaties

• gaat over
• gedefinieerd door
• heeft deel

Eigenschappen

• einddatum
• goedgekeurd
• heeft datum
• heeftAantal
• heeftGeldBedrag
• heeftTarief
• heeftTariefEenheid
• heeftZorgPrestatieCode
• startdatum

Instanties

• Verblijf in een instelling
• Volledig pakket thuis

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g:    <http://purl.org/ozo/onz-g#>
2PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
3PREFIX onz-fin:  <http://purl.org/ozo/onz-fin#>
4PREFIX xsd:      <http://www.w3.org/2001/XMLSchema#>
5
6# Indicator: Nza Kostprijs 30
7# Canonical id: MONO-0038 - "Wat is het aantal leveringen en het gedeclareerde bedrag van Zorg in Natura per combinatie van Wlz-Prestatiecode, tarief en tariefeenheid?"
8# Parameters: ?startperiode ?eindperiode
9# Ontologie: versie 3.0.0 of nieuwer
10# Vereist uitgebreide financiele dataset en RGS-zorg versie om te testen
11
12SELECT ?Wlz_Prestatiecode ?Tarief ?Tarief_eenheid (SUM(?aantal) AS ?Aantal) (SUM(?bedrag) AS ?Bedrag)
13WHERE {
14    # Dedup: een declaratie telt één keer, ongeacht hoeveel paden
15    # (zorgproces × indicatie × leveringsvorm) er naar leiden.
16    {
17        SELECT DISTINCT ?declaratie ?Wlz_Prestatiecode ?Tarief ?Tarief_eenheid ?aantal ?bedrag
18        WHERE {
19            #BIND("2024-01-01"^^xsd:date AS ?startperiode)
20            #BIND("2024-12-31"^^xsd:date AS ?eindperiode)
21
22            # Stap 1: Selecteer goedgekeurde declaraties in meetperiode
23            ?declaratie
24            a onz-g:CareInvoice ;
25            onz-g:hasDate ?date ;
26            onz-g:goedgekeurd "true"^^xsd:boolean ;
27            onz-fin:heeftZorgPrestatieCode ?Wlz_Prestatiecode ;
28            onz-fin:heeftTarief ?Tarief ;
29            onz-fin:heeftTariefEenheid ?Tarief_eenheid ;
30            onz-fin:heeftAantal ?aantal ;
31            onz-fin:heeftGeldBedrag ?bedrag ;
32            onz-g:isAbout ?zorgproces .
33
34            FILTER(?startperiode <= ?date && ?date <= ?eindperiode)
35
36            # Stap 2: Filter op Wlz-indicatie via zorgproces
37            ?zorgproces a onz-g:CureAndCareProcess ;
38            onz-g:definedBy ?indicatie .
39
40            ?indicatie a onz-zorg:WlzIndicatie ;
41            onz-g:hasPart ?lv ;
42            onz-g:startDatum ?ind_start .
43            OPTIONAL { ?indicatie onz-g:eindDatum ?ind_eind }
44            FILTER(?ind_start <= ?eindperiode && (!BOUND(?ind_eind) || ?ind_eind >= ?startperiode))
45
46            # Stap 3: Filter op Zorg in Natura (Verblijf, VPT, MPT)
47            ?lv a onz-zorg:Leveringsvorm .
48            FILTER(?lv IN (onz-zorg:instelling, onz-zorg:vpt, onz-zorg:mpt))
49        }
50    }
51}
52GROUP BY ?Wlz_Prestatiecode ?Tarief ?Tarief_eenheid
53ORDER BY ?Wlz_Prestatiecode ?Tarief ?Tarief_eenheid
54