4. Wat zijn de kosten van ingehuurd ZORG-personeel?

Concepten

• Grootboekpost
• Grootboekrekening
• Grootboekrubriek

Relaties

• deel van

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
3PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
4# Indicator: Nza Kostprijs 4
5# Canonical id: MONO-0015 - "Wat zijn de kosten van ingehuurd ZORG-personeel?"
6# Parameters: ?startperiode ?eindperiode
7# Ontologie: versie 3.0.0 of nieuwer
8# Vereist uitgebreide financiele dataset en RGS-zorg versie om te testen
9
10SELECT
11("Totaal organisatie" AS ?Indeling)
12("Totaal jaar" AS ?Periode)
13(IF(COUNT(?geld_bedrag_post) = 0, "Niet beschikbaar", (ROUND(SUM(?geld_bedrag_post) * 100) / 100)) AS ?Bedrag)
14WHERE {
15
16    # BIND("2024-01-01"^^xsd:date AS ?startperiode)
17    # BIND("2024-12-31"^^xsd:date AS ?eindperiode)
18
19    # >>> START BB: BB-011_grootboekpost_rubriek.rq
20    ?grootboekpost
21    a onz-fin:Grootboekpost ;
22    onz-fin:heeftGeldBedrag ?geld_bedrag_post ;
23    onz-g:hasDate ?boekingsdatum ;
24    onz-g:partOf ?rubriek .
25
26    # Behoud de grootboekpost alleen voor de meest specifieke rubriek,
27    # om eventuele dubbeltelling door de hiërarchische structuur rubriekcodes te voorkomen
28    FILTER NOT EXISTS {
29        ?grootboekpost onz-g:partOf ?specifiekereRubriek .
30        ?specifiekereRubriek onz-g:partOf+ ?rubriek .
31    }
32    # <<< END BB: BB-011_grootboekpost_rubriek.rq
33
34    # >>> START BB: BB-007_geldig_binnen_periode.rq
35    FILTER(?boekingsdatum >= ?startperiode && ?boekingsdatum <= ?eindperiode)
36    # <<< END BB: BB-007_geldig_binnen_periode.rq
37
38    # Vind de juiste rubrieken voor Prismant en RGS
39    {
40
41        # >>> START BB: BB-010_rubriek_rubriekcode.rq
42        VALUES ?rubriekType { onz-fin:Grootboekrubriek onz-fin:Grootboekrekening }
43        ?rubriek a ?rubriekType .
44        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
45        # <<< END BB: BB-010_rubriek_rubriekcode.rq
46
47        # >>> START BB: BB-008_zorgkostenmapping_Prismant.rq
48        VALUES (?mappingPrefix ?kostenSoort) {
49            # kosten ingehuurd ZORG personeel niet gespecificeerd in Prismant
50        }
51        # <<< END BB: BB-008_zorgkostenmapping_Prismant.rq
52
53        # filter startswith specifiek voor prismant
54        FILTER(STRSTARTS(?rubriekCode, ?mappingPrefix))
55    }
56    UNION
57    {
58
59        # >>> START BB: BB-010_rubriek_rubriekcode.rq
60        VALUES ?rubriekType { onz-fin:Grootboekrubriek onz-fin:Grootboekrekening }
61        ?rubriek a ?rubriekType .
62        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
63        # <<< END BB: BB-010_rubriek_rubriekcode.rq
64
65        # >>> START BB: BB-009_zorgkostenmapping_RGS_zorg_3_8.rq
66        VALUES (?rubriekCode ?kostenSoort) {
67            ("WKprKuwUikIzp" "Waarvan kosten ingehuurd ZORG-personeel (uitzendkrachten)")
68            ("WKprKuwUitIzp" "Waarvan kosten ingehuurd ZORG-personeel (uitzendbedrijven)")
69            ("WKprKuwMafIzp" "Waarvan kosten ingehuurd ZORG-personeel (management fee)")
70            ("WKprKuwZzpIzp" "Waarvan kosten ingehuurd ZORG-personeel (ZZP-ers)")
71            ("WKprKuwPayIzp" "Waarvan kosten ingehuurd ZORG-personeel (payrollers)")
72            ("WKprKuwOipIzp" "Waarvan kosten ingehuurd ZORG-personeel (overig ingeleend personeel)")
73        }
74        # <<< END BB: BB-009_zorgkostenmapping_RGS_zorg_3_8.rq
75
76    }
77
78}
79