8. Wat zijn de lonen en salarissen van personeel in loondienst (PIL)?

Concepten

• Grootboekpost
• Grootboekrekening
• Grootboekrubriek

Relaties

• deel van

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1PREFIX onz-g: <http://purl.org/ozo/onz-g#>
2PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
3PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
4
5# Indicator: Nza Kostprijs 8
6# Canonical id: MONO-0019 - "Wat zijn de lonen en salarissen van personeel in loondienst (PIL)?"
7# Parameters: ?meetperiode
8# Ontologie: versie 3.0.0 of nieuwer
9# Vereist uitgebreide financiele dataset en RGS-zorg versie om te testen
10
11SELECT
12("Totaal organisatie" AS ?Indeling)
13("Totaal jaar" AS ?Periode)
14(IF(COUNT(?geld_bedrag_post) = 0, "Niet beschikbaar", (ROUND(SUM(?geld_bedrag_post) * 100) / 100)) AS ?Bedrag)
15WHERE {
16
17    # BIND("2024-01-01"^^xsd:date AS ?startperiode)
18    # BIND("2024-12-31"^^xsd:date AS ?eindperiode)
19
20    # >>> START BB: BB-011_grootboekpost_rubriek.rq
21    ?grootboekpost
22    a onz-fin:Grootboekpost ;
23    onz-fin:heeftGeldBedrag ?geld_bedrag_post ;
24    onz-g:hasDate ?boekingsdatum ;
25    onz-g:partOf ?rubriek .
26
27    # Behoud de grootboekpost alleen voor de meest specifieke rubriek,
28    # om eventuele dubbeltelling door de hiërarchische structuur rubriekcodes te voorkomen
29    FILTER NOT EXISTS {
30        ?grootboekpost onz-g:partOf ?specifiekereRubriek .
31        ?specifiekereRubriek onz-g:partOf+ ?rubriek .
32    }
33    # <<< END BB: BB-011_grootboekpost_rubriek.rq
34
35    # >>> START BB: BB-007_geldig_binnen_periode.rq
36    FILTER(?boekingsdatum >= ?startperiode && ?boekingsdatum <= ?eindperiode)
37    # <<< END BB: BB-007_geldig_binnen_periode.rq
38
39    # Vind de juiste rubrieken voor Prismant en RGS
40    {
41
42        # >>> START BB: BB-010_rubriek_rubriekcode.rq
43        VALUES ?rubriekType { onz-fin:Grootboekrubriek onz-fin:Grootboekrekening }
44        ?rubriek a ?rubriekType .
45        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
46        # <<< END BB: BB-010_rubriek_rubriekcode.rq
47
48        # >>> START BB: BB-008_zorgkostenmapping_Prismant.rq
49        VALUES (?mappingPrefix ?kostenSoort) {
50            ("411" "Salarissen en vergoedingen voor in loondienst verrichte arbeid")
51            ("412" "Salarissen en vergoedingen voor in loondienst verrichte arbeid")
52            ("413" "Salarissen en vergoedingen voor in loondienst verrichte arbeid")
53            ("414" "Salarissen en vergoedingen voor in loondienst verrichte arbeid")
54            ("415" "Salarissen en vergoedingen voor in loondienst verrichte arbeid")
55            ("416" "Salarissen en vergoedingen voor in loondienst verrichte arbeid")
56            ("417" "Salarissen en vergoedingen voor in loondienst verrichte arbeid")
57            ("419" "Suppleties en andere kosten bij arbeidsongeschiktheid")
58            ("420000" "Eindheffingen loonbelasting")
59            ("420100" "Afdrachtvermindering loonbelasting")
60        }
61        # <<< END BB: BB-008_zorgkostenmapping_Prismant.rq
62
63        # filter startswith specifiek voor prismant
64        FILTER(STRSTARTS(?rubriekCode, ?mappingPrefix))
65
66    }
67    UNION
68    {
69
70        # >>> START BB: BB-010_rubriek_rubriekcode.rq
71        VALUES ?rubriekType { onz-fin:Grootboekrubriek onz-fin:Grootboekrekening }
72        ?rubriek a ?rubriekType .
73        BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
74        # <<< END BB: BB-010_rubriek_rubriekcode.rq
75
76        # >>> START BB: BB-009_zorgkostenmapping_RGS_zorg_3_8.rq
77        VALUES (?rubriekCode ?kostenSoort) {
78            ("WPerLes" "Lonen en salarissen")
79        }
80        # <<< END BB: BB-009_zorgkostenmapping_RGS_zorg_3_8.rq
81
82    }
83
84}
85