2.1.1. Gemiddeld aantal ingezette fte aan personeel in loondienst (PIL) met een zorgfunctie.

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• Zorgverlener (functie)

Relaties

• gaat over
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• heeftEindTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: NZA JMV 2.1.1
2# Parameters: -
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX time: <http://www.w3.org/2006/time#>
10
11SELECT 
12     ("Totaal_organisatie" AS ?Organisatie_onderdeel) 
13     (SUM(?gem_aantal_uren_per_overeenkomst) AS ?Gemiddeld_aantal_ingezette_fte_per_medewerker_per_week_aan_PIL_met_een_zorgfunctie)
14WHERE 
15{
16    {
17        SELECT
18            ?functie
19            (SUM(?uren) AS ?uren_per_functie)
20        WHERE
21        {
22            BIND ("2023-01-01"^^xsd:date AS ?start_periode_datum)
23            BIND ("2023-12-31"^^xsd:date AS ?eind_periode_datum) 
24            
25            # selecteer zorgverlenerfuncties die geldig zijn binnen de periode
26            ?functie a onz-pers:ZorgverlenerFunctie ;
27                onz-g:startDatum ?start_functie .
28            OPTIONAL {
29                ?functie onz-g:eindDatum ?eind_functie
30            }
31            FILTER (?start_functie <= ?eind_periode_datum && (?eind_functie >= ?eind_periode_datum || !BOUND(?eind_functie)))
32
33            # selecteer de arbeidsovereenkomst die hoort bij de functie
34            ?overeenkomst
35                onz-g:isAbout ?functie ;
36                a onz-pers:ArbeidsOvereenkomst ;
37                onz-g:isAbout ?gewerkte_periode .
38            
39            # selecteer aantal gewerkte uren binnen periode die gekoppeld zijn aan werkovereenkomst 
40            ?gewerkte_periode 
41                a onz-pers:GewerktePeriode ;
42                onz-g:hasBeginTimeStamp ?start_gewerktDT ;
43                onz-g:hasEndTimeStamp ?eind_gewerktDT ;
44                onz-g:hasQuality / onz-g:hasQualityValue / onz-g:hasDataValue ?uren .
45            BIND(STRDT(SUBSTR(STR(?start_gewerktDT),1,10), xsd:date) AS ?start_gewerkt)
46            BIND(STRDT(SUBSTR(STR(?eind_gewerktDT),1,10), xsd:date) AS ?eind_gewerkt)
47            # selecteer gewerkte tijd in de gevraagde periode
48            FILTER(?start_gewerkt >= ?start_periode_datum && ?eind_gewerkt <= ?eind_periode_datum)
49
50        } GROUP BY ?functie
51    } 
52    
53    BIND ("2023-01-01"^^xsd:date AS ?start_periode_datum)
54    BIND ("2023-12-31"^^xsd:date AS ?eind_periode_datum) 
55    ?functie a onz-pers:ZorgverlenerFunctie ;
56             onz-g:startDatum ?start_functie .
57    OPTIONAL {
58        ?functie onz-g:eindDatum ?eind_functie
59    }
60    # Bepaal aantal dagen functie in rapportageperiode
61    BIND(IF(?start_functie < ?start_periode_datum, ?start_periode_datum, ?start_functie) AS ?start_indicator)
62    BIND(IF(?eind_functie > ?eind_periode_datum || !BOUND(?eind_functie), ?eind_periode_datum, ?eind_functie) AS ?eind_indicator)
63    ?start_indicator ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?start_indicator_final .
64    ?eind_indicator ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?eind_indicator_final .
65    BIND(?eind_indicator_final - ?start_indicator_final + 1 AS ?dagen_indicator)
66
67    # bereken het totaal aantal weken dat deze persoon beschikte over een overeenkomst
68    BIND(?dagen_indicator / 7 AS ?weken_indicator)
69    # bereken het gemiddeld aantal ingezette uren per medewerker per week 
70    BIND(?uren_per_functie / (?weken_indicator * 36) AS ?gem_aantal_uren_per_overeenkomst)
71
72} 
73