2.2.1. Gemiddeld aantal contractuele fte per werknemer aan personeel in loondienst (PIL) met een zorgfunctie.

Concepten

• Arbeidsovereenkomst
• Contractomvang
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft meeteenheid
• heeft noemer kwaliteitswaarde
• heeft teller kwaliteitswaarde

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• Uur
• Week

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: NZA JMV 2.1.2
2# Parameters: -
3# Ontologie: versie 2.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX time: <http://www.w3.org/2006/time#>
10
11SELECT 
12    ("Totaal organisatie" AS ?Organisatie_onderdeel) 
13    (SUM(?gem_aantal_uren_per_overeenkomst) AS ?Gemiddeld_aantal_contractuele_fte_per_medewerker_aan_PIL_met_een_zorgfunctie)
14WHERE 
15{
16    BIND ("2023-01-01"^^xsd:date AS ?start_periode_datum)
17    BIND ("2023-12-31"^^xsd:date AS ?eind_periode_datum) 
18    
19    # selecteer zorgverlenerfuncties die geldig zijn binnen de periode
20    ?functie a onz-pers:ZorgverlenerFunctie ;
21        onz-g:startDatum ?start_functie .
22    OPTIONAL {
23        ?functie onz-g:eindDatum ?eind_functie
24    }
25    FILTER (?start_functie <= ?eind_periode_datum && (?eind_functie >= ?eind_periode_datum || !BOUND(?eind_functie)))
26
27    # selecteer de arbeidsovereenkomst die hoort bij de functie
28    ?overeenkomst
29        onz-g:isAbout ?functie ;
30        a onz-pers:ArbeidsOvereenkomst ;
31        onz-g:hasPart ?omvang .
32        
33    # Selecteer contractomvang
34    ?omvang
35        a onz-pers:ContractOmvang ;
36        onz-g:startDatum ?omvang_start ;
37        onz-g:isAbout ?omvang_waarde .
38    OPTIONAL {?omvang a onz-pers:ContractOmvang ;
39                        onz-g:eindDatum ?omvang_eind}
40    FILTER (?omvang_start <= ?eind_periode_datum && (!BOUND(?omvang_eind) || ?omvang_eind >= ?start_periode_datum))
41    
42    # Bepaal aantal dagen overeenkomst in rapportageperiode
43    BIND(IF(?omvang_start < ?start_periode_datum, ?start_periode_datum, ?omvang_start) AS ?start_indicator)
44    BIND(IF(?omvang_eind > ?eind_periode_datum || !BOUND(?omvang_eind), ?eind_periode_datum, ?omvang_eind) AS ?eind_indicator)
45    
46    ?omvang_waarde
47        onz-g:hasDataValue ?omvang_waarde_getal ;
48        onz-g:hasUnitOfMeasure ?omvang_waarde_eenheid .
49    ?omvang_waarde_eenheid
50        onz-pers:hasDenominatorQualityValue onz-g:Week ;
51        onz-pers:hasNumeratorQualityValue onz-g:Uur ;
52        onz-g:hasDataValue ?omvang_waarde_factor .
53  
54    # Bereken aantal uren per week en zet dit om naar jaar uren
55    BIND((?omvang_waarde_getal * ?omvang_waarde_factor) AS ?uren_per_week)
56    
57    ?start_indicator ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?start_indicator_final .
58    ?eind_indicator ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?eind_indicator_final .
59    BIND(?eind_indicator_final - ?start_indicator_final + 1 AS ?dagen_indicator)
60    
61    # bereken het totaal aantal weken dat deze persoon beschikte over een overeenkomst
62    BIND(?dagen_indicator / 7 AS ?weken_indicator)
63    # bereken het totaal aantal aan contractuele uren 
64    BIND(?uren_per_week * ?weken_indicator AS ?uren_per_overeenkomst)
65    # bereken het gemiddeld aantal contractuele uren per medewerker per week 
66    BIND(?uren_per_overeenkomst / (?weken_indicator * 36) AS ?gem_aantal_uren_per_overeenkomst)
67} 
68