13.2 Percentage uitstroom personeel in loondienst

Concepten

• Arbeidsovereenkomst
• Onverplaatsbaar artefact
• Vestiging
• Werkovereenkomst afspraak
• Zorgkantoor regio
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 13.2
2# Parameters: ?peildatum ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9
10SELECT 
11    (SUM(?noemer_waarde) AS ?Totaal_PIL_met_zorgfunctie_1_jaar_voor_peildatum)
12    (SUM(?teller_waarde) AS ?Uitgestroomde_PIL_met_zorgfunctie)
13    (IF(?Totaal_PIL_met_zorgfunctie_1_jaar_voor_peildatum = 0, "Ongedefineerd", 100*(?Uitgestroomde_PIL_met_zorgfunctie/?Totaal_PIL_met_zorgfunctie_1_jaar_voor_peildatum)) AS ?Percentage_zorggerelateerde_uitstroom_tov_totaal_zorggerelateerd)
14{
15    SELECT
16        ?werknemer
17        (IF (MAX(?op_peildatum_eerder) = 1, 1, 0) AS ?noemer_waarde)
18        (IF (MAX(?op_peildatum_eerder) = 1 && MAX(?op_peildatum) = 0, 1, 0) AS ?teller_waarde)
19    {
20        # BIND(xsd:date("2024-01-01") AS ?peildatum)
21   	    # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
22        BIND((?peildatum - "P1Y"^^xsd:duration) AS ?peildatum_eerder)
23
24        #Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
25        ?overeenkomst
26            a onz-pers:ArbeidsOvereenkomst ;
27            onz-pers:heeftOpdrachtnemer ?werknemer ;
28            onz-g:hasPart ?overeenkomst_afspraak .
29        ?overeenkomst_afspraak
30            a onz-pers:WerkOvereenkomstAfspraak ;
31            onz-g:isAbout ?functie ;
32            onz-g:isAbout ?locatie ;
33            onz-g:startDatum ?start_afspraak .
34        ?functie 
35            a onz-pers:ZorgverlenerFunctie .
36        OPTIONAL {
37            ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
38        }
39
40        ?locatie 
41            a onz-g:StationaryArtifact ;
42        	onz-g:partOf* ?vestiging_uri .
43        ?vestiging_uri a onz-org:Vestiging ;
44            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
45        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
46        ?pc_gebied 
47            onz-g:identifiedBy ?postcode ;
48            onz-g:partOf+ ?zk_regio .
49        ?zk_regio a onz-org:ZorgkantoorRegio .
50        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
51
52        BIND(IF(?start_afspraak <= ?peildatum && ((?eind_afspraak >= ?peildatum) || (!BOUND(?eind_afspraak))), 1, 0) AS ?op_peildatum)
53        BIND(IF(?start_afspraak <= ?peildatum_eerder && ((?eind_afspraak >= ?peildatum_eerder) || (!BOUND(?eind_afspraak))), 1, 0) AS ?op_peildatum_eerder)
54    }
55    GROUP BY ?werknemer
56}
57