2.2 Aantal verloonde uren

Concepten

• Arbeidsovereenkomst
• Functie in organisatie-rol
• Inhuurovereenkomst
• Onverplaatsbaar artefact
• Uitzendovereenkomst
• Verloonde periode
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 2.2
2# Parameters: ?jaar, ?kwartaal, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
10
11SELECT
12	?vestiging
13	# ?zorgkantoor_vestiging
14	(SUM(?verloonde_uren * ?zorg) AS ?indicator_zorg)
15	(SUM(?verloonde_uren * ?niet_zorg) AS ?indicator_niet_zorg)
16{
17    # BIND(2023 AS ?jaar)
18    # BIND("Q3" AS ?kwartaal)
19    # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
20    BIND(IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
21        IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
22        IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
23        IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
24        '')))) AS ?start_periode)
25    BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
26    
27    # Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
28    VALUES ?personeels_overeenkomst 
29    { 
30        onz-pers:ArbeidsOvereenkomst
31        onz-pers:UitzendOvereenkomst
32        onz-pers:InhuurOvereenkomst
33    }
34    ?overeenkomst 
35        a ?personeels_overeenkomst ;
36        onz-pers:heeftOpdrachtnemer ?persoon ;
37        onz-g:hasPart ?overeenkomst_afspraak .
38    ?overeenkomst_afspraak
39        a onz-pers:WerkOvereenkomstAfspraak ;
40        onz-g:startDatum ?start_afspraak .
41    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
42    FILTER(?start_afspraak <= ?eind_periode && ((?eind_afspraak >= ?start_periode) || (!BOUND(?eind_afspraak))))
43
44    ?overeenkomst_afspraak onz-g:isAbout ?functie .                
45    ?functie a onz-g:OccupationalPositionRole .
46    ?overeenkomst_afspraak onz-g:isAbout ?locatie .
47    ?locatie a onz-g:StationaryArtifact .
48
49    ?verloonde_periode
50        a onz-fin:VerloondePeriode ;
51        onz-g:definedBy ?overeenkomst ;
52        onz-g:startDatum ?datum_verloonde_periode ;
53        onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?verloonde_uren .
54    FILTER(?datum_verloonde_periode >= ?start_periode && ?datum_verloonde_periode <= ?eind_periode)
55    FILTER(?datum_verloonde_periode >= ?start_afspraak && (?datum_verloonde_periode <= ?eind_afspraak || !BOUND(?eind_afspraak)))
56
57    ?locatie onz-g:partOf* ?vestiging_uri .
58    ?vestiging_uri a onz-org:Vestiging ;
59        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
60    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
61    ?pc_gebied 
62        onz-g:identifiedBy ?postcode ;
63        onz-g:partOf+ ?zk_regio .
64    ?zk_regio a onz-org:ZorgkantoorRegio .
65    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
66    {     
67        ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
68        ?vest_nr a onz-org:Vestigingsnummer ;
69            onz-g:hasDataValue ?vestiging .
70    } UNION {
71        # Includeer ook de organisatie als geheel en label deze als vestiging
72        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
73        BIND("Totaal organisatie" AS ?vestiging)
74        BIND("n.v.t." AS ?zk_vestiging)
75    }
76    BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
77    # Bepaal of de functie op de overeenkomst van het type ZorgverlenerFunctie is
78    BIND(IF(EXISTS{?functie a onz-pers:ZorgverlenerFunctie}, 1, 0) AS ?zorg)
79    BIND(IF(?zorg = 0, 1, 0) AS ?niet_zorg)
80
81}
82GROUP BY ?vestiging ?zorgkantoor_vestiging
83ORDER BY ?vestiging