15.1. Wat is het aantal beschikbare wooneenheden?

Concepten

• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Wooneenheid
• Zorgkantoor regio

Relaties

• deel van
• deel van
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• opereert in regio
• vestiging van

Eigenschappen

• heeft datawaarde

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.1
2# Parameters: ?zorgkantoor
3# Ontologie: versie 2.2.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8
9SELECT 
10    (?vestiging AS ?Indeling)
11    (COUNT(DISTINCT ?wooneenheid) AS ?Aantal_wooneenheden)
12{
13    ?wooneenheid 
14        a onz-org:WoonEenheid ;
15        onz-g:partOf ?locatie .
16    {
17        ?locatie 
18            a onz-g:StationaryArtifact ;
19        	onz-g:partOf* ?vestiging_uri .
20        ?vestiging_uri a onz-org:Vestiging ;
21            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
22        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
23        ?pc_gebied 
24            onz-g:identifiedBy ?postcode ;
25            onz-g:partOf+ ?zk_regio .
26        ?zk_regio a onz-org:ZorgkantoorRegio .
27        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
28
29        {     
30            ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
31            ?vest_nr a onz-org:Vestigingsnummer ;
32            	onz-g:hasDataValue ?vestiging .
33        } UNION {
34            # Includeer ook de organisatie als geheel en label deze als vestiging
35            ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
36            BIND("Totaal organisatie" AS ?vestiging)
37            BIND("n.v.t." AS ?zk_vestiging)
38        }
39        BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
40    }
41}
42GROUP BY ?vestiging ?zorgkantoor_vestiging
43ORDER BY ?vestiging
44