24.1 Wat is de dekking van vaste activia door lang vermogen?

Concepten

• EindSaldo
• Grootboekpost
• Grootboekrubriek

Relaties

• deel van
• gaat over

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 24.1.0
2# Parameters: ?peildatum
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
6prefix onz-zorg:  <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9
10SELECT ?Kental ?Waarde
11WHERE {
12    {
13        SELECT (IF(SUM(IF(?jaarrekeningpost = "F Langlopende schulden", ?bedrag, 0)) = 0,
14                "Ongedefinieerd"^^xsd:string,(SUM(IF(?jaarrekeningpost = "A Vaste activa", ?bedrag, 0)) / 
15                SUM(IF(?jaarrekeningpost = "F Langlopende schulden", ?bedrag, 0)))) AS ?dvamlv)
16        WHERE {
17            {
18                SELECT ?jaarrekeningpost (SUM(?bedrag_rubriek) AS ?bedrag)
19                WHERE {
20                    # BIND("2024-12-31"^^xsd:date AS ?peildatum)
21                    BIND(?peildatum AS ?peildatum_argument)
22                    {
23                        SELECT  # totaal per rubriek
24                            (SUM(?geld_bedrag) + SUM(?saldo_waarde)/count(?saldo_waarde) AS ?bedrag_rubriek) ?rubriek ?categorie
25                        WHERE {
26                            {
27                                SELECT  # bereken het meest recente saldo per rubriek, 0 indien geen saldo
28                                    ?rubriek ?categorie
29                                    (IF(BOUND(?saldo_bedrag), ?saldo_bedrag, 0) AS ?saldo_waarde)
30                                    ?peildatum_argument
31                                    (IF(BOUND(?saldo_datum), ?saldo_datum, ?unbound) AS ?begin_datum)
32                                    ?saldo_datum ?saldo
33                                WHERE {
34                                    # BIND("2024-12-31"^^xsd:date AS ?peildatum)                                    
35									BIND(?peildatum as ?peildatum_argument)
36                                    # Dynamically identify rubrieken and assign categories
37                                    {
38                                        SELECT DISTINCT ?rubriek WHERE {
39                                            ?rubriek a onz-fin:Grootboekrubriek .
40                                            FILTER(STRSTARTS(STR(?rubriek), STR(onz-fin:)))
41                                            FILTER(REGEX(STRAFTER(STR(?rubriek), STR(onz-fin:)), "^[0-9]{6}$"))
42                                        }
43                                    }
44                                    BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
45
46                                    # Assign category based on the ?rubriekCode pattern
47                                    BIND(
48                                        COALESCE(
49
50                                            # Rubriek A
51                                            IF(STRSTARTS(?rubriekCode, "00"), "A.I", ?unbound),
52                                            IF(STRSTARTS(?rubriekCode, "01"), "A.II", ?unbound),
53                                            IF(STRSTARTS(?rubriekCode, "03"), "A.III", ?unbound),
54
55                                            # Rubriek F
56                                            IF(STRSTARTS(?rubriekCode, "07"), "F", ?unbound),
57                                            "other"
58                                        ) AS ?categorie
59                                    )
60                                    FILTER(BOUND(?categorie))
61
62                                    OPTIONAL {
63                                        ?rubriek onz-g:isAbout ?saldo .
64                                        ?saldo
65                                            a onz-fin:EindSaldo ;
66                                            onz-fin:heeftGeldBedrag ?saldo_bedrag ;
67                                            onz-g:hasDate ?saldo_datum .
68                                        FILTER (?saldo_datum <= ?peildatum_argument)
69                                    }
70                                    FILTER NOT EXISTS {
71                                        ?rubriek onz-g:isAbout ?saldo2 .
72                                        ?saldo2
73                                            onz-g:hasDate ?saldo_datum2 ;
74                                            a onz-fin:EindSaldo ;.
75                                        FILTER(?saldo2 != ?saldo)
76                                        FILTER (?saldo_datum2 <= ?peildatum_argument && ?saldo_datum2 > ?saldo_datum)
77                                    }
78                                }
79                            }
80                            OPTIONAL {
81                                ?grootboek_post
82                                    a onz-fin:Grootboekpost ;
83                                    onz-g:partOf ?rubriek ;
84                                    onz-g:hasDate ?datum ;
85                                    onz-fin:heeftGeldBedrag ?geld_bedrag_temp .
86                                FILTER (?datum <= ?peildatum_argument && (?datum > ?begin_datum || !BOUND(?begin_datum)))
87                            }
88                            BIND(IF(BOUND(?geld_bedrag_temp), ?geld_bedrag_temp, 0) AS ?geld_bedrag)
89
90                        } GROUP BY ?rubriek ?categorie
91                    }
92
93                    VALUES (?categorie ?jaarrekeningpost){
94                        ("A.I"  "A Vaste activa")
95                        ("A.II"  "A Vaste activa")
96                        ("A.III"  "A Vaste activa")
97                        ("F"      "F Langlopende schulden")
98                    }
99                } GROUP BY ?jaarrekeningpost
100            }
101        }
102    }
103    
104    BIND("Dekking  vaste activa met lang vermogen" AS ?Kental)
105    BIND(?dvamlv AS ?Waarde)
106}
107ORDER BY ?Kental