24.7 Wat is de arbeidsintensiteit PNIL?

Concepten

• Grootboekpost
• Grootboekrubriek

Relaties

• deel van

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 24.7
2# Parameters: ?startperiode, ?eindperiode
3# Ontologie: versie 3.0.0 of nieuwer
4# 
5PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
8
9SELECT ?Kental ?Waarde WHERE {
10  {
11    SELECT
12      (
13        IF(
14          BOUND(?p_totaal) && (?p_totaal != 0),
15          (COALESCE(?q_ii, 0) / xsd:decimal(?p_totaal)),
16          "Ongedefinieerd"
17        ) AS ?aipnil
18      )
19    
20    WHERE {
21      {
22        # DEEL 1: P totaal berekenen
23        SELECT (SUM(?p_bedrag) AS ?p_totaal)
24        WHERE {
25                # BIND("2024-01-01"^^xsd:date AS ?startperiode)                
26                # BIND("2024-12-31"^^xsd:date AS ?eindperiode)
27          {
28            SELECT DISTINCT ?rubriek WHERE {
29              ?rubriek a onz-fin:Grootboekrubriek .
30              FILTER(STRSTARTS(STR(?rubriek), STR(onz-fin:)))
31              FILTER(REGEX(STRAFTER(STR(?rubriek), STR(onz-fin:)), "^[0-9]{6}$"))
32            }
33          }
34
35          BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
36
37          ?grootboek_post a onz-fin:Grootboekpost ;
38                          onz-g:partOf ?rubriek ;
39                          onz-g:hasDate ?datum ;
40                          onz-fin:heeftGeldBedrag ?geld_bedrag .
41
42          FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
43
44          # P-bedragen
45          BIND(
46            IF(
47              STRSTARTS(?rubriekCode, "81") ||
48              STRSTARTS(?rubriekCode, "82") ||
49              STRSTARTS(?rubriekCode, "83") ||
50              STRSTARTS(?rubriekCode, "89") ||
51              STRSTARTS(?rubriekCode, "919") ||
52              STRSTARTS(?rubriekCode, "920") ||
53              STRSTARTS(?rubriekCode, "930"),
54              ?geld_bedrag, 0) AS ?p_bedrag
55          )
56        }
57      }
58
59      # Q.II Kosten uitbesteed werk en andere externe kosten (uitbesteed personeel) 
60      {
61        SELECT (SUM(?geld_bedrag) AS ?q_ii)
62        WHERE {
63                # BIND("2024-01-01"^^xsd:date AS ?startperiode)                
64                # BIND("2024-12-31"^^xsd:date AS ?eindperiode)          
65          {
66            SELECT DISTINCT ?rubriek WHERE {
67              ?rubriek a onz-fin:Grootboekrubriek .
68              FILTER(STRSTARTS(STR(?rubriek), STR(onz-fin:)))
69              FILTER(REGEX(STRAFTER(STR(?rubriek), STR(onz-fin:)), "^[0-9]{6}$"))
70            }
71          }
72
73          BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
74
75          BIND(
76            IF(
77              STRSTARTS(?rubriekCode, "417") ||
78              STRSTARTS(?rubriekCode, "418"),
79              "Q.II", "other"
80            ) AS ?categorie
81          )
82
83          FILTER(?categorie = "Q.II")
84
85          ?grootboek_post a onz-fin:Grootboekpost ;
86                          onz-g:partOf ?rubriek ;
87                          onz-g:hasDate ?datum ;
88                          onz-fin:heeftGeldBedrag ?geld_bedrag .
89
90          FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
91        }
92      }
93    }
94  }
95  VALUES ?Kental {
96    "Arbeidsintensiteit PNIL"
97    "Arbeidsintensiteit PNIL (%)"
98  }
99
100    BIND(
101      IF(?Kental = "Arbeidsintensiteit PNIL",
102        ?aipnil,
103        IF(DATATYPE(?aipnil) = xsd:string,
104            "Ongedefinieerd"^^xsd:string,
105            xsd:decimal(?aipnil) * 100
106        )
107    ) AS ?Waarde
108  )
109}
110ORDER BY ?Kental
111