20.5 Wat is de Reserves-Ratio?

Concepten

• EindSaldo
• Grootboekpost
• Grootboekrubriek

Relaties

• deel van
• gaat over

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 20.5.0
2# Parameters: ?peildatum, ?startperiode, ?eindperiode
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
6PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
7PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
8
9SELECT
10  ("Reserves-ratio" AS ?Kental)
11  ( 
12    IF(
13      BOUND(?bedrijfsopbrengsten) && (?bedrijfsopbrengsten != 0),
14      (xsd:decimal(?reserves) / xsd:decimal(?bedrijfsopbrengsten)),
15      "Ongedefinieerd"
16    ) AS ?Waarde
17  )
18
19  #Werkkapitaal
20WHERE {
21  {
22    SELECT
23      (SUM(IF(?jaarrekeningpost = "D Reserves", ?bedrag, 0)) AS ?reserves )
24    WHERE {
25      {
26        SELECT ?jaarrekeningpost (SUM(?bedrag_rubriek) AS ?bedrag)
27        WHERE {
28
29          {
30            SELECT ?rubriek ?categorie ((SUM(?geld_bedrag) + SUM(?saldo_waarde) / COUNT(?saldo_waarde)) AS ?bedrag_rubriek)
31            WHERE {
32              # BIND("2024-12-31"^^xsd:date AS ?peildatum)
33              BIND(?peildatum AS ?peildatum_argument)
34              {
35                SELECT DISTINCT ?rubriek WHERE {
36                  ?rubriek a onz-fin:Grootboekrubriek .
37                  FILTER(REGEX(STRAFTER(STR(?rubriek), STR(onz-fin:)), "^[0-9]{6}$"))
38                }
39              }
40              BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
41              BIND(
42                COALESCE(
43
44                  # Rubriek D
45                  IF(STRSTARTS(?rubriekCode, "05413"), "D.IV", ?unbound),
46                  IF(STRSTARTS(?rubriekCode, "05311") || STRSTARTS(?rubriekCode, "05342") || STRSTARTS(?rubriekCode, "05423"), "D.V", ?unbound),
47                  IF(STRSTARTS(?rubriekCode, "05323"), "D.VI", ?unbound),
48                  IF(STRSTARTS(?rubriekCode, "0539") || STRSTARTS(?rubriekCode, "05493") || STRSTARTS(?rubriekCode, "05915"), "D.VII", ?unbound),
49                  IF(STRSTARTS(?rubriekCode, "091"), "D.VIII", ?unbound),
50                  "other"
51                  ) AS ?categorie
52              )
53              FILTER(?categorie IN ("D.IV", "D.V", "D.VI", "D.VII", "D.VIII"))
54              OPTIONAL {
55                ?rubriek onz-g:isAbout ?saldo .
56                ?saldo a onz-fin:EindSaldo ;
57                       onz-fin:heeftGeldBedrag ?saldo_bedrag ;
58                       onz-g:hasDate ?saldo_datum .
59                FILTER(?saldo_datum <= ?peildatum_argument)
60              }
61              FILTER NOT EXISTS {
62                ?rubriek onz-g:isAbout ?otherSaldo .
63                ?otherSaldo a onz-fin:EindSaldo ;
64                            onz-g:hasDate ?otherDatum .
65                FILTER(
66                  ?otherSaldo != ?saldo
67                  && ?otherDatum <= ?peildatum_argument
68                  && ?otherDatum > ?saldo_datum
69                )
70              }
71              BIND(IF(BOUND(?saldo_bedrag), ?saldo_bedrag, 0) AS ?saldo_waarde)
72              OPTIONAL {
73                ?post a onz-fin:Grootboekpost ;
74                      onz-g:partOf ?rubriek ;
75                      onz-g:hasDate ?datum ;
76                      onz-fin:heeftGeldBedrag ?geld_bedrag_temp .
77                FILTER(
78                  ?datum <= ?peildatum_argument
79                  && (!BOUND(?saldo_datum) || ?datum > ?saldo_datum)
80                )
81              }
82              BIND(IF(BOUND(?geld_bedrag_temp), ?geld_bedrag_temp, 0) AS ?geld_bedrag)
83            }
84            GROUP BY ?rubriek ?categorie
85          }
86          VALUES (?categorie ?jaarrekeningpost) {
87            ("D.IV"   "D Reserves")
88            ("D.V"    "D Reserves")
89            ("D.VI"   "D Reserves")
90            ("D.VII"  "D Reserves")
91            ("D.VIII" "D Reserves")
92          }
93        }
94        GROUP BY ?jaarrekeningpost
95      }
96    }
97  }
98
99  # Bedrijfsopbrengsten (P)
100  {
101    SELECT ((?p_totaal) AS ?bedrijfsopbrengsten)
102    WHERE {
103      {
104        SELECT (SUM(?p_bedrag) AS ?p_totaal)
105        WHERE {
106          # BIND("2024-01-01"^^xsd:date AS ?startperiode)         
107          # BIND("2024-12-31"^^xsd:date AS ?eindperiode)
108          {
109            SELECT DISTINCT ?rubriek WHERE {
110              ?rubriek a onz-fin:Grootboekrubriek .
111              FILTER(REGEX(STRAFTER(STR(?rubriek), STR(onz-fin:)), "^[0-9]{6}$"))
112            }
113          }
114          BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
115          ?post a onz-fin:Grootboekpost ;
116                onz-g:partOf ?rubriek ;
117                onz-g:hasDate ?datum ;
118                onz-fin:heeftGeldBedrag ?geld_bedrag .
119          FILTER(?datum >= ?startperiode && ?datum <= ?eindperiode)
120          BIND(
121                IF(
122                    STRSTARTS(?rubriekCode, "81") ||
123                    STRSTARTS(?rubriekCode, "82") ||
124                    STRSTARTS(?rubriekCode, "83") ||
125                    STRSTARTS(?rubriekCode, "89") ||
126                    STRSTARTS(?rubriekCode, "919") ||
127                    STRSTARTS(?rubriekCode, "920") ||
128                    STRSTARTS(?rubriekCode, "930"),
129                    ?geld_bedrag, 0
130            ) AS ?p_bedrag
131          )
132        }
133      }
134    }
135  }
136}
137ORDER BY ?Kental
138