15.3. Hoeveel personen kunnen er per vestiging wonen?

Concepten

• Capaciteitswaarde
• Kwaliteit
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Wooneenheid
• Zorgkantoor regio

Relaties

• deel van
• deel van
• geïdentificeerd door
• heeft capaciteitsobject
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft lokaliseerbaar gebied
• opereert in regio
• vestiging van

Eigenschappen

• heeft datawaarde

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.3
2# Parameters: ?zorgkantoor
3# Ontologie: versie 2.2.0 of nieuwer
4 
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8
9SELECT 
10  (?vestiging AS ?Indeling)
11  (SUM(?unitCapacity) AS ?Capaciteit_aantal_bewoners)
12WHERE {
13  {
14    SELECT ?vestiging ?wooneenheid (MAX(?waarde) AS ?unitCapacity) ?zorgkantoor_vestiging
15    WHERE {
16      ?wooneenheid 
17          a onz-org:WoonEenheid ;
18          onz-g:hasQuality ?cap ;
19          onz-g:partOf ?locatie .
20      ?cap
21          a onz-g:Quality ;
22          onz-g:hasQualityValue ?cap_waarde .
23      ?cap_waarde a onz-g:CapacityValue ;
24          onz-g:hasDataValue ?waarde ;
25          onz-g:hasCapacityObject onz-g:Human .
26
27      {
28        ?locatie 
29            a onz-g:StationaryArtifact ;
30            onz-g:partOf* ?vestiging_uri .
31        ?vestiging_uri a onz-org:Vestiging ;
32            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
33        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
34        ?pc_gebied 
35            onz-g:identifiedBy ?postcode ;
36            onz-g:partOf+ ?zk_regio .
37        ?zk_regio a onz-org:ZorgkantoorRegio .
38        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
39
40        {     
41            ?vestiging_uri onz-g:identifiedBy ?vest_nr .
42            ?vest_nr a onz-org:Vestigingsnummer ;
43                onz-g:hasDataValue ?vestiging .
44        } UNION {
45            ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
46            BIND("Totaal organisatie" AS ?vestiging)
47            BIND("n.v.t." AS ?zk_vestiging)
48        }
49        BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
50      }
51    }
52    GROUP BY ?vestiging ?wooneenheid ?zorgkantoor_vestiging
53  }
54}
55GROUP BY ?vestiging ?zorgkantoor_vestiging
56ORDER BY ?vestiging
57