15.4.2 Hoeveel Wlz-cliënten zijn er per sector?

Concepten

• Bedrijf
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• ZorgEnVerpleegProces
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.4.2
2# Parameters: ?peildatum ?zorgkantoor 
3# Ontologie: versie 2.0.0 of nieuwer
4
5
6PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
7PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
8PREFIX onz-g: <http://purl.org/ozo/onz-g#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
11PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
12
13SELECT (?Organisatieonderdeel AS ?Indeling)        
14        (SUM(?vv) as ?VV)
15        (SUM(?lg) as ?LG)
16        (SUM(?lvg) as ?LVG)
17        (SUM(?vg) as ?VG)
18        (SUM(?zgaud) as ?ZGAUD)
19        (SUM(?zgvis) as ?ZGVIS)
20        (SUM(?ggzb) as ?GGZ_B)
21        (SUM(?ggzw) as ?GGZ_W)  
22
23WHERE
24{
25	#BIND ("2024-01-01"^^xsd:date AS ?peildatum)    
26    ?indicatie
27        a onz-zorg:WlzIndicatie ;
28        onz-g:isAbout ?client ;
29        onz-g:hasPart/onz-g:isAbout ?sector ;
30        onz-g:startDatum ?start_indicatie .
31        OPTIONAL {?indicatie onz-g:eindDatum ?eind_indicatie}
32        FILTER (?start_indicatie <= ?peildatum && (!BOUND(?eind_indicatie) || ?eind_indicatie >= ?peildatum))
33    
34    ?sector
35            a onz-zorg:LangdurigeZorgSector .
36    ?client
37        a onz-g:Human .
38    
39    # Koppel een zorgproces aan de Wlz indicaties en locaties
40    ?zorgproces a onz-g:CureAndCareProcess ;
41                onz-g:definedBy ?indicatie ;
42                onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie .
43
44    # Locatie en vestiging structuur
45    ?locatie 
46        a onz-g:StationaryArtifact ;
47        onz-g:partOf* ?vestiging_uri .
48    
49    ?vestiging_uri a onz-org:Vestiging ;
50        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
51    
52    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
53    
54    ?pc_gebied 
55        onz-g:identifiedBy ?postcode ;
56        onz-g:partOf+ ?zk_regio .
57    ?zk_regio a onz-org:ZorgkantoorRegio .
58    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
59
60    {     
61        ?vestiging_uri onz-g:identifiedBy ?vest_nr .
62        ?vest_nr a onz-org:Vestigingsnummer ;
63            onz-g:hasDataValue ?vestiging .
64        BIND(?vestiging AS ?Organisatieonderdeel)
65    } UNION {
66        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
67        ?organisatie_uri 
68            a onz-g:Business ;
69            rdfs:label ?Organisatie .
70        BIND("Totaal organisatie" AS ?Organisatieonderdeel)
71        BIND("n.v.t." AS ?zk_vestiging)
72    }
73    
74    BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
75
76    #Per financieringsstroom
77    BIND(IF(?sector = onz-zorg:VV, 1, 0) AS ?vv)
78    BIND(IF(?sector = onz-zorg:LG, 1, 0) AS ?lg)
79    BIND(IF(?sector = onz-zorg:LVG, 1, 0) AS ?lvg)
80    BIND(IF(?sector = onz-zorg:VG, 1, 0) AS ?vg)
81    BIND(IF(?sector = onz-zorg:ZGAUD, 1, 0) AS ?zgaud)
82    BIND(IF(?sector = onz-zorg:ZGVIS, 1, 0) AS ?zgvis)
83    BIND(IF(?sector = onz-zorg:GGZ-B, 1, 0) AS ?ggzb)
84    BIND(IF(?sector = onz-zorg:GGZ-W, 1, 0) AS ?ggzw)
85}
86GROUP BY ?Organisatieonderdeel
87ORDER BY ?Organisatieonderdeel
88