8.2 Welk deel van de personeelskosten zijn voor PNIL?

Concepten

• Grootboekpost
• Kostenplaats
• Vestiging
• Vestigingsnummer
• Zorgkantoor regio

Relaties

• deel van
• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• opereert in regio
• vestiging van

Eigenschappen

• heeft datawaarde
• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 8.2
2# Parameters: ?jaar, ?kwartaal, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT 
13    # ?zorgkantoor_vestiging
14	(?vestiging AS ?Indeling)
15    (SUM(?bedrag_pnil) AS ?Kosten_PNIL_Euro) 
16    (SUM(?bedrag_pil) AS ?Kosten_PIL_Euro) 
17    (IF((SUM(?bedrag_pil)+SUM(?bedrag_pnil)) = 0, "ongedefinieerd", (SUM(?bedrag_pnil) / (SUM(?bedrag_pil)+SUM(?bedrag_pnil))) * 100) AS ?Percentage_PNIL_tov_PIL_plus_PNIL)
18{
19    {
20        SELECT ?grootboek_post ?bedrag_pil ?bedrag_pnil ?vestiging_uri ?zorgkantoor_vestiging ?vestiging_label
21        {
22            {
23                SELECT DISTINCT ?grootboek_post ?bedrag_pil ?bedrag_pnil
24                {
25                    # BIND(2024 AS ?jaar)
26                    # BIND("Q2" AS ?kwartaal)                    
27                    BIND(IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
28                        IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
29                        IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
30                        IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
31                        '')))) AS ?start_periode)
32                    BIND(?start_periode + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?eind_periode)
33                    {
34                        VALUES ?rubriek_pnil { 
35                            onz-fin:WBedOvpUik 
36                            onz-fin:WBedOvpUit 
37                            onz-fin:WBedOvpMaf 
38                            onz-fin:WBedOvpZzp
39                            onz-fin:WBedOvpPay 
40                            onz-fin:WBedOvpOip 
41                            onz-fin:418
42                        }
43                        ?grootboek_post a onz-fin:Grootboekpost ;
44                            onz-g:partOf ?pnil_desc ;
45                            onz-g:hasDate ?datum ;
46                            onz-fin:heeftGeldBedrag ?bedrag_pnil .
47                        ?pnil_desc onz-g:partOf* ?rubriek_pnil
48                        BIND(0 AS ?bedrag_pil)
49                    } UNION {
50                        VALUES ?rubriek_pil { 
51                            onz-fin:WPerLes 
52                            onz-fin:WPerSol 
53                            onz-fin:411 
54                            onz-fin:412 
55                            onz-fin:413
56                            onz-fin:414 
57                            onz-fin:415 
58                            onz-fin:416 
59                            onz-fin:419 
60                            onz-fin:420000 
61                            onz-fin:420100 
62                            onz-fin:422100 
63                            onz-fin:422300 
64                            onz-fin:422400
65                            onz-fin:422410 
66                            onz-fin:422500 
67                            onz-fin:422600 
68                            onz-fin:422900
69                        }
70                        ?grootboek_post a onz-fin:Grootboekpost ;
71                            onz-g:partOf ?pil_desc ;
72                            onz-g:hasDate ?datum ;
73                            onz-fin:heeftGeldBedrag ?bedrag_pil .
74                        ?pil_desc onz-g:partOf* ?rubriek_pil
75                        
76                        MINUS { ?grootboek_post onz-g:partOf onz-fin:WPerLesOlrSvg . }
77                        BIND(0 AS ?bedrag_pnil)
78                    }
79                    FILTER (?datum >= ?start_periode && ?datum <= ?eind_periode)
80                }
81            }
82            OPTIONAL 
83            {
84                ?grootboek_post onz-g:isAbout ?kosten_plaats .
85                ?kosten_plaats a onz-fin:Kostenplaats;
86                                onz-g:isAbout ?vestiging_uri .
87                ?vestiging_uri a onz-org:Vestiging ;
88                    onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
89                BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
90                ?pc_gebied onz-g:identifiedBy ?postcode ;
91                          onz-g:partOf+ ?zk_regio .
92                ?zk_regio a onz-org:ZorgkantoorRegio .
93                ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
94                {
95                    ?vestiging_uri onz-g:identifiedBy ?vest_nr .    
96                    ?vest_nr a onz-org:Vestigingsnummer ;
97                        onz-g:hasDataValue ?vestiging_label .
98                } UNION {
99                    ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
100                    BIND("Totaal organisatie" AS ?vestiging_label)
101                    BIND("n.v.t." AS ?zk_vestiging)
102                }
103                BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zk_vestiging_temp)
104                BIND(?zk_vestiging_temp AS ?zorgkantoor_vestiging)
105            }
106        }
107    }
108    BIND(COALESCE(?vestiging_label, "Totaal") AS ?vestiging)
109}
110GROUP BY ?zorgkantoor_vestiging ?vestiging
111ORDER BY ?zorgkantoor_vestiging ?vestiging