Voorbeeld 7 Verzuimfrequentie

Concepten

• Arbeidsovereenkomst
• Werkovereenkomst afspraak
• Ziekteperiode
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft opdrachtnemer
• is participant in

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Kwaliteitsbeeld Voorbeeld 7 Verzuimfrequentie
2# Parameters: 
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13	(SUM(?aantal_ziekmeldingen) AS ?teller)
14    (COUNT(?persoon) AS ?noemer)
15    (?teller/?noemer AS ?indicator)
16{
17    SELECT
18        ?persoon
19        (COUNT(?ziekte) AS ?aantal_ziekmeldingen)
20    {
21        BIND("2024-01-01"^^xsd:date AS ?start_periode)
22        BIND("2024-12-31"^^xsd:date AS ?eind_periode)            
23        ?overeenkomst 
24            a onz-pers:ArbeidsOvereenkomst ;
25            onz-pers:heeftOpdrachtnemer ?persoon ;
26            onz-g:hasPart ?overeenkomst_afspraak .
27        ?overeenkomst_afspraak
28            a onz-pers:WerkOvereenkomstAfspraak ;
29            onz-g:startDatum ?start_afspraak .
30        OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
31        FILTER (?start_afspraak <= ?eind_periode && (?eind_afspraak >= ?start_periode || !BOUND(?eind_afspraak)))
32        ?overeenkomst_afspraak onz-g:isAbout/a onz-pers:ZorgverlenerFunctie .
33        BIND(IF(?start_afspraak < ?start_periode, ?start_periode, ?start_afspraak) AS ?start_afspraak_corr)
34        BIND(IF(?eind_afspraak > ?eind_periode || !BOUND(?eind_afspraak), ?eind_periode, ?eind_afspraak) AS ?eind_afspraak_corr)
35        OPTIONAL {
36            ?persoon onz-g:isParticipantIn ?ziekte .
37            ?ziekte 
38                a onz-pers:ZiektePeriode ;
39                onz-g:startDatum ?start_ziekte .     
40            FILTER (?start_ziekte >= ?start_afspraak_corr && ?start_ziekte <= ?eind_afspraak_corr)
41        }
42    }
43    GROUP BY ?persoon
44}
45