13.1 Percentage instroom personeel in loondienst

Concepten

• Arbeidsovereenkomst
• Onverplaatsbaar artefact
• Vestiging
• Werkovereenkomst afspraak
• Zorgkantoor regio
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• opereert in regio

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 13.1
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12    (SUM(?noemer_waarde) AS ?Aantal_PIL_met_zorgfunctie)
13    (SUM(?teller_waarde) AS ?Aantal_ingestroomde_PIL_met_zorgfunctie)
14    (IF(?Aantal_PIL_met_zorgfunctie = 0, "Ongedefinieerd", 100*(?Aantal_ingestroomde_PIL_met_zorgfunctie/?Aantal_PIL_met_zorgfunctie)) AS ?Percentage_zorggerelateerde_instroom_tov_totaal_zorggerelateerd)
15{
16    SELECT
17		?werknemer
18        (IF (MAX(?op_peildatum) = 1, 1, 0) AS ?noemer_waarde)
19        (IF (MAX(?op_peildatum) = 1 && MAX(?op_peildatum_eerder) = 0, 1, 0) AS ?teller_waarde)
20    {
21        # BIND(xsd:date("2024-08-01") AS ?peildatum)
22   	    # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
23        BIND((?peildatum - "P1Y"^^xsd:duration) AS ?peildatum_eerder)
24
25        #Bepaal filter voor definitie van overeenkomsten die geldig zijn voor personeelsleden
26        ?overeenkomst
27            a onz-pers:ArbeidsOvereenkomst ;
28            onz-pers:heeftOpdrachtnemer ?werknemer ;
29            onz-g:hasPart ?overeenkomst_afspraak .
30        ?overeenkomst_afspraak
31            a onz-pers:WerkOvereenkomstAfspraak ;
32            onz-g:isAbout ?functie ;
33            onz-g:isAbout ?locatie ;
34            onz-g:startDatum ?start_afspraak .
35        ?functie 
36            a onz-pers:ZorgverlenerFunctie .
37        OPTIONAL {
38            ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
39        }
40
41        ?locatie 
42            a onz-g:StationaryArtifact ;
43        	onz-g:partOf* ?vestiging_uri .
44        ?vestiging_uri a onz-org:Vestiging ;
45            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
46        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
47        ?pc_gebied 
48            onz-g:identifiedBy ?postcode ;
49            onz-g:partOf+ ?zk_regio .
50        ?zk_regio a onz-org:ZorgkantoorRegio .
51        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
52
53        BIND(IF(?start_afspraak <= ?peildatum && ((?eind_afspraak >= ?peildatum) || (!BOUND(?eind_afspraak))), 1, 0) AS ?op_peildatum)
54        BIND(IF(?start_afspraak <= ?peildatum_eerder && ((?eind_afspraak >= ?peildatum_eerder) || (!BOUND(?eind_afspraak))), 1, 0) AS ?op_peildatum_eerder)
55    }
56    GROUP BY ?werknemer
57}