15.3. Aantal personen dat per vestiging kan wonen

Concepten

• Capaciteitswaarde
• Kwaliteit
• Mens
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Wooneenheid
• Zorgkantoor regio

Relaties

• deel van
• deel van
• geïdentificeerd door
• heeft capaciteitsobject
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft lokaliseerbaar gebied
• opereert in regio
• vestiging van

Eigenschappen

• heeft datawaarde

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 15.3
2# Parameters: ?zorgkantoor
3# Ontologie: versie 2.2.0 of nieuwer
4 
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8
9SELECT ?vestiging (SUM(?unitCapacity) AS ?capaciteit)
10WHERE {
11  {
12    SELECT ?vestiging ?wooneenheid (MAX(?waarde) AS ?unitCapacity) ?zorgkantoor_vestiging
13    WHERE {
14      ?wooneenheid 
15          a onz-org:WoonEenheid ;
16          onz-g:hasQuality ?cap ;
17          onz-g:partOf ?locatie .
18      ?cap
19          a onz-g:Quality ;
20          onz-g:hasQualityValue ?cap_waarde .
21      ?cap_waarde a onz-g:CapacityValue ;
22          onz-g:hasDataValue ?waarde ;
23          onz-g:hasCapacityObject onz-g:Human .
24
25      {
26        ?locatie 
27            a onz-g:StationaryArtifact ;
28            onz-g:partOf* ?vestiging_uri .
29        ?vestiging_uri a onz-org:Vestiging ;
30            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
31        BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
32        ?pc_gebied 
33            onz-g:identifiedBy ?postcode ;
34            onz-g:partOf+ ?zk_regio .
35        ?zk_regio a onz-org:ZorgkantoorRegio .
36        ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
37
38        {     
39            ?vestiging_uri onz-g:identifiedBy ?vest_nr .
40            ?vest_nr a onz-org:Vestigingsnummer ;
41                onz-g:hasDataValue ?vestiging .
42        } UNION {
43            ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
44            BIND("Totaal organisatie" AS ?vestiging)
45            BIND("n.v.t." AS ?zk_vestiging)
46        }
47        BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
48      }
49    }
50    GROUP BY ?vestiging ?wooneenheid ?zorgkantoor_vestiging
51  }
52}
53GROUP BY ?vestiging ?zorgkantoor_vestiging
54ORDER BY ?vestiging
55