4.1 Gemiddelde contractomvang personeel op een peildatum

Concepten

• Arbeidsovereenkomst
• Contractomvangwaarde
• Functie in organisatie-rol
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft meeteenheid
• heeft opdrachtnemer
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 4.1 
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX time: <http://www.w3.org/2006/time#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10
11SELECT
12    ?vestiging
13    # ?zorgkantoor_vestiging
14	(IF(COUNT(DISTINCT ?zorg_persoon)=0, "Ongedefineerd", SUM(?teller_waarde * ?zorg)/COUNT(DISTINCT ?zorg_persoon)) AS ?zorggerelateerd)
15	(IF(COUNT(DISTINCT ?niet_zorg_persoon)=0, "Ongedefineerd", SUM(?teller_waarde * ?niet_zorg)/COUNT(DISTINCT ?niet_zorg_persoon)) AS ?niet_zorggerelateerd)
16
17{
18    # BIND(2023 AS ?jaar)
19    # BIND("Q3" AS ?kwartaal)
20    # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
21
22    # BIND($(peildatum) AS ?peildatum)
23
24    ?overeenkomst 
25        a onz-pers:ArbeidsOvereenkomst ;
26        onz-pers:heeftOpdrachtnemer ?persoon ;
27        onz-g:hasPart ?overeenkomst_afspraak .
28    ?overeenkomst_afspraak
29        a onz-pers:WerkOvereenkomstAfspraak ;
30        onz-g:startDatum ?start_afspraak .
31    OPTIONAL {
32        ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
33    }
34    FILTER (?start_afspraak <= ?peildatum && (?eind_afspraak >= ?peildatum || !BOUND(?eind_afspraak)))
35
36    # Bepaal de omvang van het contract in uren per week
37    ?overeenkomst_afspraak onz-g:hasPart/onz-g:isAbout ?contract_omvang .
38    ?contract_omvang
39        a onz-pers:ContractOmvangWaarde ;
40        onz-g:hasDataValue ?omvang_waarde ;
41        onz-g:hasUnitOfMeasure ?omvang_eenheid .
42    ?omvang_eenheid onz-g:hasDataValue ?omvang_correctie .
43    BIND(?omvang_waarde*?omvang_correctie AS ?teller_waarde)
44    
45    # bepaal vestiging en zorgkantoor regio voor iedere contractafspraak
46    ?overeenkomst_afspraak onz-g:isAbout ?locatie .
47    ?locatie 
48        a onz-g:StationaryArtifact ;
49        onz-g:partOf* ?vestiging_uri .
50    ?vestiging_uri a onz-org:Vestiging ;
51        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
52    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
53    ?pc_gebied 
54        onz-g:identifiedBy ?postcode ;
55        onz-g:partOf+ ?zk_regio .
56    ?zk_regio a onz-org:ZorgkantoorRegio .
57    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
58
59    {     
60        ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
61        ?vest_nr a onz-org:Vestigingsnummer ;
62            onz-g:hasDataValue ?vestiging .
63    } UNION {
64        # Includeer ook de organisatie als geheel en label deze als vestiging
65        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
66        BIND("Totaal organisatie" AS ?vestiging)
67        BIND("n.v.t." AS ?zk_vestiging)
68    }
69    BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
70
71    # Bepaal of de functie op de overeenkomst van het type ZorgverlenerFunctie is
72    ?overeenkomst_afspraak onz-g:isAbout ?functie .
73    ?functie a onz-g:OccupationalPositionRole .
74    BIND(IF (EXISTS {?functie a onz-pers:ZorgverlenerFunctie}, 1, 0) AS ?zorg)
75    BIND(IF (?zorg = 0, 1, 0) AS ?niet_zorg)
76    BIND(IF(?zorg = 1, ?persoon, ?unbound) AS ?zorg_persoon)
77    BIND(IF(?niet_zorg = 1, ?persoon, ?unbound) AS ?niet_zorg_persoon)
78} 
79GROUP BY ?vestiging ?zorgkantoor_vestiging
80