14.2 Aantal cliënten per leveringsvorm

Concepten

• Leveringsvorm
• Mens
• Verpleegproces
• Vestiging
• Vestigingsnummer
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft perdurantlocatie
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• indicatie behandeling
• startdatum

Instanties

• VV Beschermd verblijf met intensieve palliatief-terminale zorg
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging
• Verblijf in een instelling

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 14.2
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11
12SELECT
13    ?vestiging
14	?leveringsvorm
15    (COUNT (DISTINCT(?client)) AS ?indicator)
16WHERE
17{ 
18    # BIND ($(peildatum) AS ?peildatum)
19    VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
20
21    #selecteer de zorgprocessen op de vestigingen die voldoen aan de inclusiecriteria
22    ?zorgproces
23        a onz-zorg:NursingProcess ;
24        onz-g:definedBy ?indicatie ;
25        onz-g:hasPerdurantLocation ?locatie ;
26        onz-g:startDatum ?start_zorgproces .
27    	OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
28    	FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces))))
29    ?locatie 
30        onz-g:partOf* ?vestiging_uri .
31    ?vestiging_uri a onz-org:Vestiging ;
32                    onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
33    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
34    ?pc_gebied 
35        onz-g:identifiedBy ?postcode ;
36        onz-g:partOf+ ?zk_regio .
37    ?zk_regio a onz-org:ZorgkantoorRegio .
38    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
39	
40    {     
41        ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
42        ?vest_nr a onz-org:Vestigingsnummer ;
43        	onz-g:hasDataValue ?vestiging .
44    } UNION {
45        # Includeer ook de organisatie als geheel en label deze als vestiging
46        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
47        BIND("Totaal organisatie" AS ?vestiging)
48        BIND("n.v.t." AS ?zk_vestiging)
49    }
50    BIND(IF(!BOUND(?zk_vestiging), ?zorgkantoor, ?zk_vestiging) AS ?zorgkantoor_vestiging)
51    
52    #selecteer de bijbehordene indicatie, om unieke clienten te kunnen bepalen
53    ?indicatie 
54        onz-g:hasPart ?zorgprofiel ;
55        onz-g:hasPart ?lv ;
56        onz-g:isAbout ?client .
57  		OPTIONAL {?indicatie onz-zorg:heeftIndicatieBehandeling ?behandeling}
58        BIND(IF(BOUND(?behandeling), ?behandeling, "false"^^xsd:boolean) AS ?incl_behandeling)
59    ?client a onz-g:Human .
60  	?lv
61    	a onz-zorg:Leveringsvorm ;
62        rdfs:label ?leveringsvorm_label ;
63        BIND(IF(?lv != onz-zorg:instelling, ?leveringsvorm_label, 
64      		IF(?incl_behandeling, "Verblijf met behandeling", "Verblijf zonder behandeling"))
65      		AS ?leveringsvorm)		
66} 
67GROUP BY ?vestiging ?leveringsvorm
68ORDER BY ?vestiging ?leveringsvorm