1.3 Wat is het totaal aantal medewerkers?

Concepten

• Arbeidsovereenkomst bepaalde tijd
• Arbeidsovereenkomst beroeps begeleidende leerweg
• Arbeidsovereenkomst onbepaalde tijd
• Inhuurovereenkomst
• Mens
• Oproepovereenkomst
• Stage-overeenkomst
• Uitzendovereenkomst
• Vrijwilligersovereenkomst
• Werkovereenkomst afspraak

Relaties

• heeft deel
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 1.3
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-org: <http://purl.org/ozo/onz-org#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
9
10SELECT ?Periode
11    ("Organisatie" AS ?Indeling)
12    (COUNT(DISTINCT ?totaal_persoon) AS ?Totaal)
13    (COUNT(DISTINCT ?persoon_onbepaald) AS ?Aantal_medewerkers_onbepaalde_tijd)
14    (COUNT(DISTINCT ?persoon_bepaald) AS ?Aantal_medewerkers_bepaalde_tijd)
15    (COUNT(DISTINCT ?persoon_oproep) AS ?Aantal_medewerkers_oproep)
16    (COUNT(DISTINCT ?persoon_bbl) AS ?Aantal_medewerkers_BBL)
17    (COUNT(DISTINCT ?persoon_inhuur) AS ?Aantal_medewerkers_inhuur)
18    (COUNT(DISTINCT ?persoon_uitzend) AS ?Aantal_medewerkers_uitzend)
19    (COUNT(DISTINCT ?persoon_stage) AS ?Aantal_medewerkers_stage)
20    (COUNT(DISTINCT ?persoon_vrijwilliger) AS ?Aantal_medewerkers_vrijwilliger)
21WHERE {
22      #BIND(2024 AS ?jaar)  
23      VALUES ?kw { 1 2 3 4 0 }
24
25      BIND( xsd:date(CONCAT(STR(?jaar), "-",
26                        IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
27           )) AS ?p_start )
28      BIND( xsd:date(CONCAT(STR(?jaar), "-",
29               IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
30           )) AS ?p_eind )
31      BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
32    
33    # Selecteer álle werkovereenkomsten 
34    VALUES ?type_overeenkomst {
35        onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd
36        onz-pers:ArbeidsOvereenkomstBepaaldeTijd
37        onz-pers:OproepOvereenkomst
38        onz-pers:ArbeidsOvereenkomstBBL
39        onz-pers:InhuurOvereenkomst
40        onz-pers:UitzendOvereenkomst
41        onz-pers:StageOvereenkomst
42        onz-pers:VrijwilligersOvereenkomst
43    }
44    
45    # Alle overeenkomsten binnen de periode
46    ?overeenkomst 
47        a ?type_overeenkomst ;
48        onz-pers:heeftOpdrachtnemer ?persoon ;
49        onz-g:hasPart ?overeenkomst_afspraak .
50    ?overeenkomst_afspraak
51        a onz-pers:WerkOvereenkomstAfspraak ;
52        onz-g:startDatum ?start_afspraak .
53    OPTIONAL {?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak}
54    FILTER(?start_afspraak <= ?p_eind && (?eind_afspraak >= ?p_start || !BOUND(?eind_afspraak)))
55    ?persoon a onz-g:Human .
56    
57    # Conditionele binding per contract type
58    BIND(IF(?type_overeenkomst = onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd, ?persoon, ?unbound) AS ?persoon_onbepaald)
59    BIND(IF(?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBepaaldeTijd, ?persoon, ?unbound) AS ?persoon_bepaald)
60    BIND(IF(?type_overeenkomst = onz-pers:OproepOvereenkomst, ?persoon, ?unbound) AS ?persoon_oproep)
61    BIND(IF(?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBBL, ?persoon, ?unbound) AS ?persoon_bbl)
62    BIND(IF(?type_overeenkomst = onz-pers:InhuurOvereenkomst, ?persoon, ?unbound) AS ?persoon_inhuur)
63    BIND(IF(?type_overeenkomst = onz-pers:UitzendOvereenkomst, ?persoon, ?unbound) AS ?persoon_uitzend)
64    BIND(IF(?type_overeenkomst = onz-pers:StageOvereenkomst, ?persoon, ?unbound) AS ?persoon_stage)
65    BIND(IF(?type_overeenkomst = onz-pers:VrijwilligersOvereenkomst, ?persoon, ?unbound) AS ?persoon_vrijwilliger)
66    
67    # Voor totaal kolom
68    BIND(?persoon AS ?totaal_persoon)
69    
70
71}
72GROUP BY ?Periode
73ORDER BY ?Periode