2.10. Wat is het aantal contractuele FTE personeel in loondienst (PIL) zonder zorgfunctie op 1 januari?

Concepten

• Arbeidsovereenkomst
• Contractomvang
• Contractomvangwaarde
• Functie in organisatie-rol
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft meeteenheid
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• FTE (36 uur per week)

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.10
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer 
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT ("Totaal Organisatie" AS ?Indeling)
12	   (ROUND(SUM(?fte) * 100) / 100 AS ?Aantal_FTE)
13{
14    {
15        SELECT 
16            ?overeenkomst_afspraak
17        {
18            #BIND(2024 AS ?jaar)
19			BIND(xsd:date(CONCAT(STR(?jaar), "-01-01")) AS ?peildatum)
20            
21            ?overeenkomst 
22                a onz-pers:ArbeidsOvereenkomst ; # personeel in loondienst
23                onz-pers:heeftOpdrachtnemer ?persoon ;
24                onz-g:hasPart ?overeenkomst_afspraak .
25            ?overeenkomst_afspraak
26                a onz-pers:WerkOvereenkomstAfspraak ;
27                onz-g:startDatum ?start_afspraak ;
28            	onz-g:isAbout ?functie .
29            OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
30            FILTER(?start_afspraak <= ?peildatum && ((?eind_afspraak >= ?peildatum) || (!BOUND(?eind_afspraak)))) # geldig op peildatum
31   			
32            ?functie a onz-g:OccupationalPositionRole .
33            FILTER NOT EXISTS { ?functie a onz-pers:ZorgverlenerFunctie }
34
35        }
36    }
37    ?overeenkomst_afspraak onz-g:hasPart ?omvang . # haal omvang van alle geldige afspraken op
38    ?omvang 
39        a onz-pers:ContractOmvang ;
40        onz-g:isAbout ?omvang_waarde .
41    ?omvang_waarde
42        a onz-pers:ContractOmvangWaarde ;
43        onz-g:hasDataValue ?omvang_waarde_getal ;
44        onz-g:hasUnitOfMeasure ?omvang_waarde_eenheid .
45    ?omvang_waarde_eenheid onz-g:hasDataValue ?eenheid_factor .
46    BIND(IF(?omvang_waarde_eenheid = onz-pers:fte_36, ?omvang_waarde_getal, ?omvang_waarde_getal / 36 * ?eenheid_factor) AS ?fte) # omrekenen naar fte_36
47}
48