2.17. Wat is het gemiddeld aantal ingezette FTE personeel in loondienst (PIL) met een zorgfunctie per kwartaal?

Concepten

• Arbeidsovereenkomst
• Gewerkte periode
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• gedefinieerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.17
2# Parameters: ?jaar
3# Ontologie: versie 3.0
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT ?Periode 
12       ("Totaal organisatie" AS ?Indeling)
13		   ?Aantal_FTE
14WHERE {
15  {
16    SELECT ?Periode
17           (FLOOR(SUM(?inzet_uren) / 141 / IF(?Periode = "Totaal jaar", 12, 3)) AS ?Aantal_FTE)
18    WHERE {
19      #BIND(2024 AS ?jaar)            
20      VALUES ?kw { 1 2 3 4 0 }
21
22      BIND( xsd:date(CONCAT(STR(?jaar), "-",
23                        IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
24           )) AS ?p_start )
25      BIND( xsd:date(CONCAT(STR(?jaar), "-",
26               IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
27           )) AS ?p_eind )
28      BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
29		
30      ?overeenkomst
31          a onz-pers:ArbeidsOvereenkomst ;
32          onz-pers:heeftOpdrachtnemer ?persoon ;
33          onz-g:startDatum ?start_overeenkomst ;
34          onz-g:hasPart ?overeenkomst_afspraak .
35      OPTIONAL { ?overeenkomst onz-g:eindDatum ?eind_overeenkomst }
36      FILTER (?start_overeenkomst  <= ?p_eind && (?eind_overeenkomst >= ?p_start || !BOUND(?eind_overeenkomst)))
37
38      ?overeenkomst_afspraak
39          a onz-pers:WerkOvereenkomstAfspraak ;
40          onz-g:isAbout ?functie ;
41          onz-g:startDatum ?start_afspraak .
42      OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
43      FILTER (?start_afspraak <= ?p_eind && (?eind_afspraak >= ?p_start || !BOUND(?eind_afspraak)))
44
45      ?functie a onz-pers:ZorgverlenerFunctie .
46
47      ?inzet
48          a onz-pers:GewerktePeriode ;
49          onz-g:definedBy ?overeenkomst ;
50          onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
51          onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?inzet_uren .
52      BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
53      FILTER(?start_inzet >= ?p_start && ?start_inzet <= ?p_eind)
54      FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
55
56    }
57    GROUP BY ?Periode
58  }
59}
60ORDER BY ?Periode
61