2.7. Wat is het aantal vrijwilligers?

Concepten

• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Vrijwilligersovereenkomst
• Werkovereenkomst afspraak

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.7
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT 
12    ?Periode
13    (?vestiging AS ?Indeling)
14    (COUNT (DISTINCT ?persoon) AS ?Aantal_vrijwilligers)
15
16WHERE {
17    #BIND(2024 AS ?jaar)
18    VALUES ?kw { 0 1 2 3 4 }
19
20    # Periodegrenzen
21    BIND( xsd:date(CONCAT(STR(?jaar), "-",
22            IF(?kw=2,"04-01", 
23            IF(?kw=3,"07-01", 
24            IF(?kw=4,"10-01", "01-01")))
25        )) AS ?p_start ) .
26    BIND( xsd:date(CONCAT(STR(?jaar), "-",
27            IF(?kw=1,"03-31", 
28            IF(?kw=2,"06-30", 
29            IF(?kw=3,"09-30", "12-31")))
30        )) AS ?p_eind ) .
31
32    BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode ) .
33    
34    ?overeenkomst 
35        a onz-pers:VrijwilligersOvereenkomst ;
36        onz-pers:heeftOpdrachtnemer ?persoon ;
37        onz-g:hasPart ?overeenkomst_afspraak .
38    ?overeenkomst_afspraak
39        a onz-pers:WerkOvereenkomstAfspraak ;
40        onz-g:startDatum ?start_afspraak .
41    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
42    FILTER(?start_afspraak <= ?p_eind && ((?eind_afspraak >= ?p_start) || (!BOUND(?eind_afspraak))))
43
44    ?overeenkomst_afspraak onz-g:isAbout ?locatie . 
45	?locatie a onz-g:StationaryArtifact ;
46	           onz-g:partOf* ?vestiging_uri .
47    ?vestiging_uri a onz-org:Vestiging .
48    {  
49        	?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
50        	?vest_nr a onz-org:Vestigingsnummer ;
51            onz-g:hasDataValue ?vestiging .
52    } UNION {
53        	# Includeer ook de organisatie als geheel en label deze als vestiging
54        	?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
55        	BIND("Totaal organisatie" AS ?vestiging)
56    }
57}
58
59GROUP BY ?Periode ?vestiging
60ORDER BY ?vestiging ?Periode