2.19. Wat is de verhouding tussen het aantal personeelsleden met een zorgverlenersfunctie en het aantal cliënten?

Concepten

• Gewerkte periode
• Mens
• Onverplaatsbaar artefact
• Verpleegproces
• Vestiging
• Vestigingsnummer
• Werkovereenkomst
• Werkovereenkomst afspraak
• Wlz-indicatie
• Zorgverlener (functie)

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

Instanties

• VV Beschermd verblijf met intensieve palliatief-terminale zorg
• VV Beschermd wonen met intensieve dementiezorg
• VV Beschermd wonen met intensieve verzorging en verpleging
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op begeleiding
• VV Beschermd wonen met zeer intensieve zorg, vanwege specifieke aandoeningen, met de nadruk op verzorging en verpleging
• VV Beschut wonen met intensieve begeleiding en uitgebreide verzorging
• VV Herstelgerichte behandeling met verpleging en verzorging
• Verblijf in een instelling

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.19
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
12PREFIX time: <http://www.w3.org/2006/time#>
13
14SELECT 
15    ?Periode
16    (?vestiging AS ?Indeling)
17    ?Aantal_ingezette_uren
18    ?Aantal_ligdagen
19	(IF(?Aantal_ingezette_uren != 0, ROUND( (?Aantal_ligdagen / (?Aantal_ingezette_uren / 24)) * 100 ) / 100,"Ongedefinieerd")  AS ?Aantal_cliënten_tov_1_medewerker)
20WHERE {
21  {
22    SELECT
23      ?Periode
24      ?vestiging
25      (SUM(?gewerkte_uren) AS ?Aantal_ingezette_uren)
26    WHERE {
27      #BIND(2024 AS ?jaar)
28      VALUES ?kw { 1 2 3 4 0 }
29
30      BIND( xsd:date(CONCAT(STR(?jaar), "-",
31            IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
32          )) AS ?p_start )
33      BIND( xsd:date(CONCAT(STR(?jaar), "-",
34            IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
35          )) AS ?p_eind )
36      BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
37
38      ?overeenkomst 
39        a onz-pers:WerkOvereenkomst ;
40        onz-g:hasPart ?overeenkomst_afspraak .
41      ?overeenkomst_afspraak
42        a onz-pers:WerkOvereenkomstAfspraak ;
43        onz-g:isAbout / a onz-pers:ZorgverlenerFunctie ;
44        onz-g:isAbout ?locatie_afspraak ;
45        onz-g:startDatum ?start_afspraak .
46      OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak . }
47      ?locatie_afspraak a onz-g:StationaryArtifact .
48
49      FILTER(?start_afspraak <= ?p_eind && ((?eind_afspraak >= ?p_start) || (!BOUND(?eind_afspraak))))
50      BIND(IF(?start_afspraak < ?p_start, ?p_start, ?start_afspraak) AS ?start_afspraak_corr)
51      BIND(IF(?eind_afspraak > ?p_eind || !BOUND(?eind_afspraak), ?p_eind, ?eind_afspraak) AS ?eind_afspraak_corr)
52
53      ?inzet
54        a onz-pers:GewerktePeriode ;
55        onz-g:definedBy ?overeenkomst ;
56        onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
57        onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?gewerkte_uren .
58      OPTIONAL { ?inzet onz-g:hasPerdurantLocation ?locatie_inzet . }
59      BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
60
61      FILTER(?start_inzet >= ?start_afspraak_corr && (?start_inzet <= ?eind_afspraak_corr || !BOUND(?eind_afspraak_corr)))
62      BIND(IF(BOUND(?locatie_inzet), ?locatie_inzet, ?locatie_afspraak) AS ?locatie)
63
64	  ?locatie a onz-g:StationaryArtifact ;
65	           onz-g:partOf* ?vestiging_uri .
66      ?vestiging_uri a onz-org:Vestiging .
67      {  
68        	?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
69        	?vest_nr a onz-org:Vestigingsnummer ;
70            onz-g:hasDataValue ?vestiging .
71      } UNION {
72        	# Includeer ook de organisatie als geheel en label deze als vestiging
73        	?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
74        	BIND("Totaal organisatie" AS ?vestiging)
75      }
76    }
77    GROUP BY ?Periode ?vestiging 
78  }
79  {
80    SELECT
81      ?Periode
82      ?vestiging
83      (SUM(?ligdagen) AS ?Aantal_ligdagen)
84    WHERE {
85      #BIND(2024 AS ?jaar)
86      VALUES ?kw { 1 2 3 4 0 }
87
88      # Periode-bepaling (zelfde patroon)
89      BIND( xsd:date(CONCAT(STR(?jaar), "-",
90            IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
91          )) AS ?start_periode )
92      BIND( xsd:date(CONCAT(STR(?jaar), "-",
93            IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
94          )) AS ?eind_periode )
95      BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
96
97      VALUES ?zorgprofiel { onz-zorg:4VV onz-zorg:5VV onz-zorg:6VV onz-zorg:7VV onz-zorg:8VV onz-zorg:9BVV onz-zorg:10VV }
98
99      ?indicatie 
100        a onz-zorg:WlzIndicatie ;
101        onz-g:startDatum ?start_indicatie ;
102        onz-g:hasPart ?zorgprofiel ;
103        onz-g:hasPart onz-zorg:instelling ;
104        onz-g:isAbout ?client .
105      OPTIONAL { ?indicatie onz-g:eindDatum ?eind_indicatie . }
106      ?client a onz-g:Human .
107
108      FILTER(?start_indicatie <= ?eind_periode && ((?eind_indicatie >= ?start_periode) || (!BOUND(?eind_indicatie))))
109      BIND(IF(?start_indicatie < ?start_periode, ?start_periode, ?start_indicatie) AS ?start_indicatie_corr)
110      BIND(IF(?eind_indicatie > ?eind_periode || !BOUND(?eind_indicatie), ?eind_periode, ?eind_indicatie) AS ?eind_indicatie_corr)
111
112      ?zorgproces
113        a onz-zorg:NursingProcess ;
114        onz-g:definedBy ?indicatie ;
115        onz-g:hasPerdurantLocation ?locatie ;
116        onz-g:startDatum ?start_zorgproces .
117      OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces . }
118      FILTER(?start_zorgproces <= ?eind_periode && ((?eind_zorgproces >= ?start_periode) || (!BOUND(?eind_zorgproces))))
119      BIND(IF(?start_zorgproces < ?start_indicatie_corr, ?start_indicatie_corr, ?start_zorgproces) AS ?start_zorgproces_corr)
120      BIND(IF(?eind_zorgproces > ?eind_indicatie_corr || !BOUND(?eind_indicatie), ?eind_indicatie_corr, ?eind_indicatie) AS ?eind_zorgproces_corr)
121
122      ?start_zorgproces_corr ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?start_dag_reken .
123      ?eind_zorgproces_corr ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?eind_dag_reken .
124      BIND(?eind_dag_reken - ?start_dag_reken + 1 AS ?ligdagen)
125
126	  ?locatie a onz-g:StationaryArtifact ;
127	           onz-g:partOf* ?vestiging_uri .
128      ?vestiging_uri a onz-org:Vestiging .
129      {  
130        	?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
131        	?vest_nr a onz-org:Vestigingsnummer ;
132            onz-g:hasDataValue ?vestiging .
133      } UNION {
134        	# Includeer ook de organisatie als geheel en label deze als vestiging
135        	?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
136        	BIND("Totaal organisatie" AS ?vestiging)
137      }
138    }
139    GROUP BY ?Periode ?vestiging 
140	}
141}
142ORDER BY ?Periode ?Indeling
143