2.9. Wat is het aantal contractuele FTE personeel in loondienst (PIL) met een zorgfunctie op de peildatum, 1 januari?

Concepten

• Arbeidsovereenkomst
• Contractomvangwaarde
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft meeteenheid
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.9
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g:    <http://purl.org/ozo/onz-g#>
7PREFIX xsd:      <http://www.w3.org/2001/XMLSchema#>
8PREFIX onz-org:  <http://purl.org/ozo/onz-org#>
9
10SELECT
11    (?indeling AS ?Indeling)
12    (ROUND(SUM(?fte36) * 100) / 100 AS ?Aantal_FTE)
13
14WHERE {
15    # BIND(2024 AS ?jaar)
16    BIND(xsd:integer(?jaar) AS ?_jaar)
17
18    # Peildatum: 1 januari van het opgegeven jaar
19    BIND(xsd:date(CONCAT(STR(?_jaar), "-01-01")) AS ?peildatum)
20
21    # Deze indicator wordt alleen op organisatieniveau gerapporteerd
22    BIND("Totaal organisatie" AS ?indeling)
23
24    # Arbeidsovereenkomsten (PIL) met afspraken die geldig zijn op de peildatum
25    ?overeenkomst
26        a onz-pers:ArbeidsOvereenkomst ;
27        onz-pers:heeftOpdrachtnemer ?persoon ;
28        onz-g:hasPart ?overeenkomst_afspraak .
29
30    ?overeenkomst_afspraak
31        a onz-pers:WerkOvereenkomstAfspraak ;
32        onz-g:isAbout ?functie ;
33        onz-g:startDatum ?start_afspraak .
34
35    OPTIONAL {
36        ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak
37    }
38
39    FILTER (
40        ?start_afspraak <= ?peildatum &&
41        ( !BOUND(?eind_afspraak) || ?eind_afspraak >= ?peildatum )
42    )
43
44    # Beperk tot afspraken met een zorgverlenersfunctie
45    ?functie a onz-pers:ZorgverlenerFunctie .
46
47    # Contractomvang ophalen en omrekenen naar uren per week
48    ?overeenkomst_afspraak onz-g:hasPart/onz-g:isAbout ?contract_omvang .
49
50    ?contract_omvang
51        a onz-pers:ContractOmvangWaarde ;
52        onz-g:hasDataValue ?omvang_waarde ;
53        onz-g:hasUnitOfMeasure ?omvang_eenheid .
54
55    ?omvang_eenheid onz-g:hasDataValue ?omvang_correctie .
56
57    # aantal contracturen per week voor deze afspraak
58    BIND(?omvang_waarde * ?omvang_correctie AS ?uren_per_week)
59
60    # Omrekening naar FTE36: 1 FTE = 36 uur per week
61    BIND(?uren_per_week / 36 AS ?fte36)
62}
63GROUP BY ?indeling
64