2.38. Wat is de verzuimfrequentie (excl. zwangerschapsverlof)?

Concepten

• Arbeidsovereenkomst
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Ziekteperiode
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.38
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX onz-g: <http://purl.org/ozo/onz-g#>
10PREFIX onz-org: <http://purl.org/ozo/onz-org#>
11PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
12
13SELECT 
14	?Periode
15    (?vestiging AS ?Indeling)
16	(?zk_regio_code AS ?Zorgkantoorregio_code)
17    (COUNT(DISTINCT ?persoon) AS ?Aantal_personeelsleden_in_loondienst)
18    (SUM(?meldingen) AS ?Aantal_nieuwe_ziekmeldingen)
19    (IF(COUNT(DISTINCT ?persoon)=0,
20        "Ongedefinieerd",
21        (ROUND( ( (xsd:decimal(SUM(?meldingen)) / xsd:decimal(COUNT(DISTINCT ?persoon))) * 100.0 ) * 100.0 ) / 100.0)
22    ) AS ?Verzuimfrequentie_excl_zwangerschap)
23{
24    {
25        SELECT 
26        	?Periode
27        	?zk_regio_code
28            ?persoon
29            ?vestiging
30            (COUNT(DISTINCT ?ziekte) AS ?meldingen)
31        {
32	  		#BIND(2024 AS ?jaar)             
33          	VALUES ?kw { 1 2 3 4 0 }         
34
35          	# Periode-bepaling
36          	BIND( xsd:date(CONCAT(STR(?jaar), "-",
37                IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
38              )) AS ?start_periode )
39          	BIND( xsd:date(CONCAT(STR(?jaar), "-",
40                IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
41              )) AS ?eind_periode)
42          	BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
43
44            ?overeenkomst 
45                a onz-pers:ArbeidsOvereenkomst ; # personeel in loondienst
46                onz-pers:heeftOpdrachtnemer ?persoon ;
47                onz-g:hasPart ?overeenkomst_afspraak .
48            ?overeenkomst_afspraak
49                a onz-pers:WerkOvereenkomstAfspraak ;
50                onz-g:isAbout ?locatie ;
51                onz-g:startDatum ?start_afspraak .
52            OPTIONAL {?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak}
53            FILTER (?start_afspraak <= ?eind_periode && ((!BOUND(?eind_afspraak)) || (?eind_afspraak >= ?start_periode)))
54			
55            OPTIONAL {
56                  VALUES ?type_verzuim {
57                    onz-pers:ZiektePeriode
58                    # onz-pers:ZwangerschapsVerlof
59                  }
60
61                  ?ziekte
62                    a ?type_verzuim ;
63                    onz-g:definedBy ?overeenkomst ;
64                    onz-g:startDatum ?start_ziekte_periode .
65
66                  # Alleen nieuwe ziekmeldingen binnen meetperiode
67                  FILTER(?start_ziekte_periode >= ?start_periode && ?start_ziekte_periode <= ?eind_periode)
68
69                  # Zorg dat ziekmelding valt binnen looptijd van de afspraak 
70                  FILTER(?start_ziekte_periode >= ?start_afspraak && ( !BOUND(?eind_afspraak) || ?start_ziekte_periode <= ?eind_afspraak )
71                  )
72                }
73
74          {
75           # Tak 1: echte vestiging + afleiding zorgkantoorregio
76           ?locatie onz-g:partOf* ?vestiging_uri .
77           ?vestiging_uri a onz-org:Vestiging ;
78           onz-g:identifiedBy ?vest_nr ;
79           onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
80           ?vest_nr a onz-org:Vestigingsnummer ; onz-g:hasDataValue ?vestiging .
81
82           BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
83           ?pc_gebied onz-g:identifiedBy ?postcode ; onz-g:partOf+ ?zk_regio .
84           ?zk_regio a onz-org:ZorgkantoorRegio .
85           }
86           UNION
87           {
88           # Tak 2: totaal organisatie, laat ?zk_regio ongebonden (leeg in output)
89           ?locatie onz-g:partOf* ?vestiging_uri .
90           ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
91           BIND("Totaal organisatie" AS ?vestiging)
92           }
93
94           BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
95        }
96        GROUP BY ?Periode ?persoon ?vestiging ?zk_regio_code
97    }
98}
99GROUP BY ?Periode ?vestiging ?zk_regio_code
100ORDER BY ?Periode ?vestiging 
101