2.6. Welk deel van de arbeidsovereenkomsten is voor bepaalde tijd?

Concepten

• Arbeidsovereenkomst bepaalde tijd
• Arbeidsovereenkomst onbepaalde tijd
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.6
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g:    <http://purl.org/ozo/onz-g#>
7PREFIX onz-org:  <http://purl.org/ozo/onz-org#>
8PREFIX rdfs:     <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd:      <http://www.w3.org/2001/XMLSchema#>
10
11SELECT
12    ?Periode
13    (?vestiging AS ?Indeling)
14    (SUM(?bepaald_flag) AS ?Aantal_arbeidsovereenkomsten_bepaalde_tijd)
15    ((SUM(?bepaald_flag) + SUM(?onbepaald_flag)) AS ?Aantal_arbeidsovereenkomsten_voor_bepaalde_en_onbepaalde_tijd)
16    (IF( (SUM(?bepaald_flag) + SUM(?onbepaald_flag)) > 0,
17        ROUND(10000 * SUM(?bepaald_flag) / (SUM(?bepaald_flag) + SUM(?onbepaald_flag))) / 100 ,
18        0
19    ) AS ?Procent_bepaalde_tijd)
20WHERE {
21    {
22    SELECT
23        ?Periode
24        ?vestiging
25        ?overeenkomst
26        (MAX(?is_bepaald)   AS ?bepaald_flag)
27        (MAX(?is_onbepaald) AS ?onbepaald_flag)
28    WHERE {
29        #BIND(2023 AS ?jaar)
30        VALUES ?kw { 1 2 3 4 0 }  # 0 = Totaal jaar
31        BIND(xsd:integer(?jaar) AS ?_jaar)
32
33        BIND( IF(?kw=0,
34                xsd:date(CONCAT(STR(?_jaar), "-01-01")),
35                xsd:date(CONCAT(STR(?_jaar), "-",
36                                IF(?kw=1,"01-01",
37                                    IF(?kw=2,"04-01",
38                                    IF(?kw=3,"07-01","10-01")))))
39                ) AS ?p_start )
40
41        BIND( IF(?kw=0,
42                xsd:date(CONCAT(STR(?_jaar), "-12-31")),
43                xsd:date(CONCAT(STR(?_jaar), "-",
44                                IF(?kw=1,"03-31",
45                                    IF(?kw=2,"06-30",
46                                    IF(?kw=3,"09-30","12-31")))))
47                ) AS ?p_eind )
48
49        BIND( IF(?kw=0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
50
51        VALUES ?type_overeenkomst {
52        onz-pers:ArbeidsOvereenkomstBepaaldeTijd
53        onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd
54        }
55
56        ?overeenkomst a ?type_overeenkomst ;
57                    onz-g:hasPart ?overeenkomst_afspraak .
58
59        ?overeenkomst_afspraak
60            a onz-pers:WerkOvereenkomstAfspraak ;
61            onz-g:isAbout ?locatie ;
62            onz-g:startDatum ?start_afspraak .
63        OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
64
65        FILTER( ?start_afspraak <= ?p_eind &&
66                ( !BOUND(?eind_afspraak) || ?eind_afspraak >= ?p_start ) )
67
68	  ?locatie a onz-g:StationaryArtifact ;
69	           onz-g:partOf* ?vestiging_uri .
70      ?vestiging_uri a onz-org:Vestiging .
71      {  
72        	?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
73        	?vest_nr a onz-org:Vestigingsnummer ;
74            onz-g:hasDataValue ?vestiging .
75      } UNION {
76        	# Includeer ook de organisatie als geheel en label deze als vestiging
77        	?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
78        	BIND("Totaal organisatie" AS ?vestiging)
79      }
80
81        BIND( IF(?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBepaaldeTijd,   1, 0) AS ?is_bepaald )
82        BIND( IF(?type_overeenkomst = onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd, 1, 0) AS ?is_onbepaald )
83    }
84    GROUP BY ?Periode ?vestiging ?overeenkomst
85    }
86}
87GROUP BY ?Periode ?vestiging
88ORDER BY ?Periode
89